blob: 38705d769763327fe444b734ce7b7f4acea805b5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: Thor77 <thor77 at thor77 dot org>
# Contributor: Sebastian Krebs <sebastian[at]krebs[dot]one>
pkgname=telegraf-bin
pkgver=1.30.0
pkgrel=1
pkgdesc="An open source agent for collecting metrics and data on the system; Binary release"
arch=('i686' 'x86_64' 'armv6h' 'armv7h' 'aarch64')
url="https://github.com/influxdata/telegraf"
license=('MIT')
conflicts=('telegraf')
backup=('etc/telegraf/telegraf.conf')
install=telegraf.install
source_i686=("https://dl.influxdata.com/telegraf/releases/telegraf-${pkgver}_linux_i386.tar.gz")
source_x86_64=("https://dl.influxdata.com/telegraf/releases/telegraf-${pkgver}_linux_amd64.tar.gz")
source_armv6h=("https://dl.influxdata.com/telegraf/releases/telegraf-${pkgver}_linux_armhf.tar.gz")
source_armv7h=("https://dl.influxdata.com/telegraf/releases/telegraf-${pkgver}_linux_armhf.tar.gz")
source_aarch64=("https://dl.influxdata.com/telegraf/releases/telegraf-${pkgver}_linux_arm64.tar.gz")
source=('telegraf.sysusers' 'telegraf.tmpfiles' 'LICENSE')
sha256sums=('31c038721ff674519a506418b0d70045e2c51115a78a5939743886c44ef5e1bb'
'36b309e79422ddbaf6067f814c8bd69bd842cc662c3c9dbbf507ee5716282779'
'bece49bfc61abbb9d0b69bebb47955a44617ada83186c95db5651cd40c0a867a')
sha256sums_i686=('664e23db0ade7b40f4410b218b7a814ac62364d0558a4dff4ac0b7ef3a7c8927')
sha256sums_x86_64=('e7153ae102d090f9296d8c647cd6b5975d18532c4ccfe74895c950450c2968f6')
sha256sums_armv6h=('4c3a31c873c97265a402c2ead781297c15d3de346e4d879c08c11d0d515c8932')
sha256sums_armv7h=('4c3a31c873c97265a402c2ead781297c15d3de346e4d879c08c11d0d515c8932')
sha256sums_aarch64=('6c82fc5ec6b72d75074165263e7dc31114e83cfbc002617052c6c5983d8fa9e4')
package() {
cd "$srcdir"
install -Dm644 telegraf.sysusers "$pkgdir/usr/lib/sysusers.d/telegraf.conf"
install -Dm644 telegraf.tmpfiles "$pkgdir/usr/lib/tmpfiles.d/telegraf.conf"
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/telegraf/LICENSE"
cd "telegraf-$pkgver"
install -Dm755 usr/bin/telegraf "$pkgdir/usr/bin/telegraf"
install -Dm644 usr/lib/telegraf/scripts/telegraf.service "$pkgdir/usr/lib/systemd/system/telegraf.service"
install -Dm644 etc/telegraf/telegraf.conf "$pkgdir/etc/telegraf/telegraf.conf"
install -Dm644 etc/logrotate.d/telegraf "$pkgdir/etc/logrotate.d/telegraf"
}
|