blob: 2580cce4ba3b83bf087eb8f59899e5d12d6f9f62 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
|
# Maintainer: Sameer Hoosen <tabhooked@gmail.com>
# Official package maintainer: Sven-Hendrik Haase <svenstaro@gmail.com>
# Based on telegram-desktop-dev by: Giovanni 'ItachiSan' Santini <giovannisantini93@yahoo.it>
# Contributor: hexchain <i@hexchain.org>
# Thanks to Dan Elkouby <streetwalrus@codewalr.us> for some of the custom patch ideas!
# https://github.com/Streetwalrus/dotfiles/blob/master/scripts/telegram-desktop
# Thanks Nicholas Guriev <guriev-ns@ya.ru> for the patches!
# https://github.com/mymedia2/tdesktop
pkgname=telegram-desktop-udf-patched
pkgver=2.5.8
pkgrel=1
pkgdesc='Telegram Desktop client with several personal patches'
arch=('x86_64')
url="https://desktop.telegram.org/"
license=('GPL3')
depends=(
'hunspell' 'ffmpeg' 'hicolor-icon-theme' 'lz4' 'minizip' 'openal' 'ttf-opensans'
'qt5-imageformats' 'xxhash' 'libdbusmenu-qt5' 'kwayland' 'gtk3'
)
makedepends=('cmake' 'git' 'ninja' 'python' 'range-v3' 'tl-expected' 'microsoft-gsl' 'libtg_owt')
provides=('telegram-desktop')
conflicts=('telegram-desktop')
source=(
"https://github.com/telegramdesktop/tdesktop/releases/download/v${pkgver}/tdesktop-${pkgver}-full.tar.gz"
# Custom patches
"always_delete_for_everyone.patch"
"always_clear_history_for_everyone.patch"
"always_pin_without_notify.patch"
"always_send_as_photo_or_album.patch"
"force_gtk_integration.patch"
)
sha512sums=(
'12258eb5119fcd9db6d1be38224678ed67c76a24de59909d2ef0268587df2432f6f076273581f016f8ba593b95bb7c0e02062b77bad194ff5a211b35fa743d7b'
# Custom patches
'e88fa96024efc6176c818d0a46684e0ee1fb3a7bdadb323ad3b29f736209c80b6c31b135cf84389e7e2bbd614e57b241e4437c94b6fd114e73cfc418bf130015'
'4a7e9de924bbf32fb4cd24ffa2764bcf49e0540bba649829b180da20a62810d4a21ebf11529d4eca22c9ceaa93b434ca3fbfd0b636795f8109ea4e1eddbff8f3'
'fb69ecf4de4c57f4f226be6e704ceb811916715c23a5908d8c2d21970676df64c86b58123429b55c43dafea89f92da33119fa71988df6912f8fcd07ba2c8579c'
'fbf1c8311ead2a63471fcf5a17156ca4b5d1b582c7cd838fd97fafeca79146670d0a73805a144a9a0ab12a33ec5a0ec4c5cbeb07c6a9e3878fe293edd428b91c'
'a1063cad603d367bd0fed5edc452e100a45ed779ba8c706450e5e5662ff52fc17b3c4fc72a5814642f77a5508a187f4a864b7f374dc5ccbbe52b483a4d45a3c5'
)
prepare() {
cd tdesktop-$pkgver-full/cmake
# force webrtc link to libjpeg
echo "target_link_libraries(external_webrtc INTERFACE jpeg)" | tee -a external/webrtc/CMakeLists.txt
cd "$srcdir/tdesktop-$pkgver-full"
# custom patches
patch -Np1 -i "$srcdir/always_delete_for_everyone.patch"
patch -Np1 -i "$srcdir/always_clear_history_for_everyone.patch"
patch -Np1 -i "$srcdir/always_pin_without_notify.patch"
patch -Np1 -i "$srcdir/always_send_as_photo_or_album.patch"
patch -Np1 -i "$srcdir/force_gtk_integration.patch"
}
build() {
cd tdesktop-$pkgver-full
# Turns out we're allowed to use the official API key that telegram uses for their snap builds:
# https://github.com/telegramdesktop/tdesktop/blob/8fab9167beb2407c1153930ed03a4badd0c2b59f/snap/snapcraft.yaml#L87-L88
# Thanks @primeos!
cmake . \
-B build \
-G Ninja \
-DCMAKE_INSTALL_PREFIX="/usr" \
-DCMAKE_BUILD_TYPE=Release \
-DTDESKTOP_API_ID=611335 \
-DTDESKTOP_API_HASH=d524b414d21f4d37f08684c1df41ac9c \
-DTDESKTOP_LAUNCHER_BASENAME="telegramdesktop" \
-DDESKTOP_APP_SPECIAL_TARGET=""
ninja -C build
}
package() {
cd tdesktop-$pkgver-full
DESTDIR=$pkgdir ninja -C build install
}
|