PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62

# Maintainer: Giovanni 'ItachiSan' Santini <giovannisantini93@yahoo.it>
# Contributor: Antonio Rojas <arojas@archlinux.org>

_gitname=telegram-qt
pkgbase=telegram-qt-git
pkgname=(telegram-qt-git telegram-qt5-git telegram-qt6-git)
pkgver=r2660.cd033446
pkgrel=1
pkgdesc="Qt bindings for the Telegram protocol"
arch=(i686 x86_64)
url="https://github.com/Kaffeine/telegram-qt"
license=(GPL)
depends=(openssl)
makedepends=(cmake git qt5-declarative qt6-declarative)
source=("git+https://github.com/Kaffeine/$_gitname")
md5sums=('SKIP')

pkgver() {
  cd $_gitname
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  echo "--> Configuring QT5 library"
  cmake -S $_gitname -B build_qt5 \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -DCMAKE_BUILD_TYPE=RelWithDebInfo \
    -DBUILD_WITH_QT_VERSION=Qt5

  echo "--> Configuring QT6 library"
  cmake -S $_gitname -B build_qt6 \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -DCMAKE_BUILD_TYPE=RelWithDebInfo \
    -DBUILD_WITH_QT_VERSION=Qt6
}

build() {
  echo "--> Building QT5 library"
  cmake --build build_qt5
  echo "--> Building QT6 library"
  cmake --build build_qt6
}

package_telegram-qt5-git() {
  provides=(telegram-qt)
  conflicts=(telegram-qt)
  depends+=(qt5-declarative)
  echo "--> Installing QT5 library"
  DESTDIR="$pkgdir" cmake --install build_qt5
}

package_telegram-qt-git() {
  depends+=(telegram-qt5-git)
}

package_telegram-qt6-git() {
  depends+=(qt6-declarative)
  echo "--> Installing QT6 library"
  DESTDIR="$pkgdir" cmake --install build_qt6
}