blob: 1fb78bb6ef54867d72786e1826104a4f6db42e9b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: j.r <j.r@jugendhacker.de>
_pkgname=telegram-tg
pkgname=$_pkgname-git
pkgver=0.17.0.r8.c2f5fca
pkgrel=3
pkgdesc="terminal telegram client that really works"
arch=(any)
url="https://github.com/paul-nameless/tg"
license=('Unlicense')
depends=('python-telegram=0.15.0' 'python3' 'python-setuptools')
makedepends=('git')
optdepends=(
'libnotify: for notifications, you could also use other programs: see config'
'ffmpeg: to record voice msgs and upload videos correctly'
'urlview: to choose urls when there is multiple in message, use URL_VIEW in config file to use another app, it should accept urls in stdin'
'ranger: can be used to choose file when sending, customizable with FILE_PICKER_CMD'
'nnn: can be used to choose file when sending, customizable with FILE_PICKER_CMD'
'fzf: to create groups and secret chats, used for single and multiple user selection'
)
provides=("$_pkgname")
conflicts=("$_pkgname")
source=("$_pkgname::git+https://github.com/paul-nameless/tg.git"
"0001-Change-setup.py-to-accept-new-python-telegram-ver.patch"
"0002-Update-to-TDLib-1.7.10.patch")
md5sums=('SKIP'
'1977134e8c8fcd093d7081877711255d'
'84f26c2df9961f4f88f5f8b20daa0b18')
pkgver() {
cd "$srcdir/$_pkgname"
printf "%s" "$(git describe --long --tags | sed 's/\([^-]*-\)g/r\1/;s/-/./g;s/\(v\)\(.*\)/\2/')"
}
prepare() {
cd "$srcdir/$_pkgname"
patch -p1 -i "$srcdir/0001-Change-setup.py-to-accept-new-python-telegram-ver.patch"
patch -p1 -i "$srcdir/0002-Update-to-TDLib-1.7.10.patch"
}
build() {
cd "$srcdir/$_pkgname"
python3 setup.py build
}
package() {
cd "$srcdir/$_pkgname"
python3 setup.py install --root="$pkgdir" --optimize=1 --skip-build
}
|