summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 16ed8e7c2d3eefaa9b43be3554fd4d06d09da64b (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
# Maintainer: Alexey Andreyev <aa13q@ya.ru>

_gitname=brain-im
pkgname=telepathy-brain-im-git
pkgver=r13.bc31484
pkgrel=1
pkgdesc="Telepathy IM client"
arch=(i686 x86_64 armv7h aarch64)
url="https://telepathy.freedesktop.org/"
license=(GPL)
depends=('telepathy-qt')
makedepends=(cmake git)
provides=(telepathy-brain-im)
conflicts=(telepathy-brain-im)
source=("git+https://github.com/TelepathyIM/$_gitname")
md5sums=('SKIP')

pkgver() {
  cd $_gitname
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../$_gitname \
    -DENABLE_QML_CLIENT=TRUE \
    -DENABLE_QML=TRUE \
    -DINSTALL_QML_IMPORT_DIR=lib/qt/qml \
    -DUSE_TELEPATHY=TRUE \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -DCMAKE_INSTALL_LIBEXECDIR=lib/telepathy \
    -DCMAKE_BUILD_TYPE=Release \
    -DQT_VERSION_MAJOR=5
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
  mkdir -p "$pkgdir"/usr/bin
  cp "examples/qmlclient/$_gitname" "$pkgdir"/usr/bin
}