blob: f74dbb3bcd7adb920d7cd407d8642168acc77c7b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Maintainer: Ariel AxionL <arielaxionl@gmail.com | axionl@aosc.io>
# Maintainer: Maarten de Boer <maarten@cloudstek.nl>
# Maintainer: Christian Heusel <christian@heusel.eu>
# Contributor: Johannes Pfrang <johannespfrang+arch @ gmail.com>
# Contributor: Emanuele 'Lele aka eldios' Calo' <xeldiosx@gmail.com>
_pkgname=teleport
pkgname=teleport-bin
pkgver=13.1.5
pkgrel=1
pkgdesc="Modern SSH server for teams managing distributed infrastructure"
arch=('i386' 'x86_64' 'armv7h' 'aarch64')
url="https://goteleport.com/"
license=('Apache')
provides=('teleport' 'tctl' 'tsh' 'tbot')
conflicts=('teleport')
install=teleport.install
source=("teleport.service"
"teleport@.service"
"teleport.install")
# The teleport servers do not allow for byte ranges to continue download so we set -C0
# https://aur.archlinux.org/packages/teleport-bin#comment-906339
DLAGENTS=('https::/usr/bin/curl -qgb "" -fL -C0 --retry 3 --retry-delay 3 -o %o %u')
source_i386=("teleport-bin-${pkgver}-i386.tar.gz::https://get.gravitational.com/teleport-v${pkgver}-linux-386-bin.tar.gz")
source_x86_64=("teleport-bin-${pkgver}-x86_64.tar.gz::https://get.gravitational.com/teleport-v${pkgver}-linux-amd64-bin.tar.gz")
source_armv7h=("teleport-bin-${pkgver}-armv7h.tar.gz::https://get.gravitational.com/teleport-v${pkgver}-linux-arm-bin.tar.gz")
source_aarch64=("teleport-bin-${pkgver}-aarch64.tar.gz::https://get.gravitational.com/teleport-v${pkgver}-linux-arm64-bin.tar.gz")
sha256sums=('22fd1ee136e9422458740811c9946de447105f26e87dbbc8daa35d17bd1f3894'
'21ca4e56c9c5e1ce11570894e85ded853e26e91cc2e16ed9114b3d6a2c5c22ef'
'ce2dd61cae3c0c3684e7e629f98b77551e66ddedca2194250a34f0efbc674f3a')
sha256sums_i386=('0ce0ff2e6513e030566caec82e6a162bd3b0447320c307826be30b252c03b77b')
sha256sums_x86_64=('21aab317ada257dea9d31ece2545082e477887a7a974c4bacc92ede34069506c')
sha256sums_armv7h=('8781877c2700013796ba536b57c93f8d96e2a100e4b611706dd9c38876a9a74b')
sha256sums_aarch64=('a505c580caa26b67d4e0392063346bce7cb7a115193fa059596762d3c1748d99')
options=(!strip)
package() {
cd "${_pkgname}"
# Install binaries
install -Dm755 teleport "${pkgdir}/usr/bin/teleport"
install -Dm755 tctl "${pkgdir}/usr/bin/tctl"
install -Dm755 tsh "${pkgdir}/usr/bin/tsh"
install -Dm755 tbot "${pkgdir}/usr/bin/tbot"
# Install services
install -Dm644 ${srcdir}/teleport.service "${pkgdir}/usr/lib/systemd/system/teleport.service"
install -Dm644 ${srcdir}/teleport@.service "${pkgdir}/usr/lib/systemd/system/teleport@.service"
# Copy example files
install -dm755 "${pkgdir}/usr/share/teleport"
cp -r examples "${pkgdir}/usr/share/teleport/"
}
|