blob: eedb99b456e8cb739d81fbf4f97e34b2769c7218 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Vlad Pirlog <(firstname) at (lastname) dot net>
pkgname=temporal-cli
pkgver='0.10.3'
pkgrel=1
pkgdesc='CLI for running Temporal Server and interacting with various parts of Temporal'
arch=('x86_64')
url='https://github.com/temporalio/cli'
license=('MIT')
depends=('glibc')
makedepends=('go')
source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
b2sums=('a4d9730e813b8bd7413a0b36643d5fa71adf639473d9a9580136df3d2a06d31e50a6d39ed3f24e3d461c97dc4cd2613abc6fca10a6db2a43967df401d86d27b4')
build() {
cd "cli-$pkgver"
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -mod=readonly -modcacherw"
go build \
-ldflags="-linkmode=external -X github.com/temporalio/cli/headers.Version=${pkgver}" \
-o dist/ \
./cmd/...
./dist/temporal completion bash > temporal.bash
./dist/temporal completion zsh > temporal.zsh
./dist/docgen
}
package() {
cd "cli-$pkgver"
install -Dm755 ./dist/temporal -t "${pkgdir}/usr/bin"
install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
install -d "${pkgdir}/usr/share/doc/${pkgname}"
cp -r ./docs/* "${pkgdir}/usr/share/doc/${pkgname}"
install -Dm644 temporal.bash "${pkgdir}/usr/share/bash-completion/completions/temporal"
install -Dm644 temporal.zsh "${pkgdir}/usr/share/zsh/site-functions/_temporal"
}
|