PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59

# Maintainer:

_pkgname="termite"
pkgname="$_pkgname-git"
pkgver=16.9.r2.gbd9945f
pkgrel=1
pkgdesc='A simple VTE-based terminal'
url="https://github.com/aperezdc/termite"
license=('LGPL-2.0-or-later')
arch=('x86_64')

depends=(
  'gnutls'
  'gtk3'
  'pcre2'
  'vte-common'
)
makedepends=(
  'git'
  'glib2-devel'
  'gperf'
  'meson'
)

provides=("$_pkgname=${pkgver%%.r*}")
conflicts=("$_pkgname")

_pkgsrc="$_pkgname"
source=(
  "$_pkgsrc"::"git+$url.git"
  "aperezdc.vte"::"git+https://github.com/aperezdc/vte.git"
)
sha256sums=(
  'SKIP'
  'SKIP'
)

backup=(etc/xdg/termite/config)

prepare() {
  local _vte_hash=$(grep -Po '(?<=revision = )[a-f0-9]+$' "$_pkgsrc/subprojects/vte.wrap")
  ln -s "$srcdir/aperezdc.vte" "$_pkgsrc/subprojects/vte"
  git -c advice.detachedHead=false -C "aperezdc.vte" checkout -f "$_vte_hash"
}

pkgver() {
  cd "$_pkgsrc"
  git describe --long --tags --exclude='*[a-zA-Z][a-zA-Z]*' \
    | sed -E 's/^v//;s/([^-]*-g)/r\1/;s/-/./g'
}

build() {
  arch-meson build "$_pkgsrc"
  meson compile -C build
}

package() {
  meson install -C build --skip-subprojects vte --destdir "$pkgdir"
}