summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 5009981f1cf557dcf9a06153ebab9b8e662493ed (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
# $Id$
# Maintainer: unit73e <unit73e at gmail dot com>
# Contributor: blimpy <0087yugbocaj@gmail.com>
# Contributor: Daniel Micay <danielmicay@gmail.com>

pkgbase=termite-nocsd
pkgname=('termite-nocsd')
pkgver=14
pkgrel=1
pkgdesc="A simple VTE-based terminal without GTK client side decorations. Perfect for wayland+sway users."
url="https://github.com/thestinger/termite/"
license=('LGPL')
conflicts=('termite')
provides=('termite')
arch=('x86_64')
depends=('gtk3' 'pcre2' 'gnutls' 'vte-common')
makedepends=('git' 'ncurses' 'intltool' 'gperf' 'gtk-doc')
_vtever=0.54.2.a
source=("${pkgbase}::git+https://github.com/thestinger/termite#tag=v${pkgver}"
        "git+https://github.com/thestinger/vte-ng#tag=${_vtever}"
        "termite-util::git+https://github.com/thestinger/util"
        "termite.patch")
sha256sums=('SKIP'
            'SKIP'
	    'SKIP'
            '4319296a88502b0a0397704177047cf7b0d39816b87d0f477a92ced4d1f16715')

prepare() {
  cd "${pkgbase}"
  patch -Np1 -i "${srcdir}/termite.patch" "${srcdir}/termite-nocsd/termite.cc"

  cd ../vte-ng
  echo 'sources: $(BUILT_SOURCES)' >> src/Makefile.am 
  NOCONFIGURE=1 ./autogen.sh

  cd "../${pkgbase}"
  git submodule init
  git config --local submodule.util.url "${srcdir}/termite-util"
  git submodule update
}

build() {
  cd vte-ng
  ./configure \
    --prefix="${srcdir}/vte-static" \
    --localedir="/usr/share/${pkgbase}/locale" \
    --enable-static \
    --disable-shared \
    enable_introspection=no \
    enable_vala=no \
    --disable-gtk-doc \
    --disable-glade-catalogue
  make -C src sources install-exec install-data -j 1 # makefile bug does not allow -j
  make install-pkgconfigDATA

  cd "../${pkgbase}"
  export PKG_CONFIG_PATH="${srcdir}/vte-static/lib/pkgconfig"
  make
}

package_termite-nocsd() {
  depends+=('termite-terminfo')
  backup=(etc/xdg/termite/config)

  make -C vte-ng/po DESTDIR="${pkgdir}" install-data
  make -C "${pkgbase}" DESTDIR="${pkgdir}" PREFIX=/usr install
  rm -r "${pkgdir}/usr/share/terminfo"
}