PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61

# Maintainer: Samuel Corsi-House <chouse.samuel@gmail.com>
# Contributor: Artemii Sudakov <finziyr@yandex.ru>

pkgname=termius-app
_pkgname=${pkgname%-*}
pkgver=7.38.2
pkgrel=1
pkgdesc="Desktop SSH Client"
url="https://termius.com/"
arch=('x86_64')
license=('custom')
conflicts=('termius')
provides=('termius')
# Depends: libgtk-3-0, libnotify4, libnss3, libxss1, libxtst6, xdg-utils, libuuid1, libappindicator3-1, libsecret-1-0
depends=('gtk3' 'libnotify' 'nss' 'libxss' 'libxtst' 'xdg-utils' 'at-spi2-core' 'libappindicator-gtk3' 'libsecret')
makedepends=('grep' 'sed')
# Now I will specify the dependencies that I got from the ldd output
# You can view them by executing:
# for dep in $(ldd /opt/Termius/termius-app | sed 's/^[[:blank:]]*//' | cut -d " " -f 3); do pacman -Qoq $dep; done | sort -u | tr '\n' ' '

#depends+=(alsa-lib atk at-spi2-atk at-spi2-core avahi bzip2 cairo dbus e2fsprogs expat fontconfig freetype2 fribidi gcc-libs gdk-pixbuf2 glib2 glibc gmp gnutls graphite gtk3 harfbuzz keyutils krb5 libcap libcloudproviders libcups libdatrie libdrm libepoxy libffi libgcrypt libgpg-error libidn2 libjpeg-turbo libp11-kit libpng libtasn1 libthai libtiff libunistring libx11 libxau libxcb libxcomposite libxcursor libxdamage libxdmcp libxext libxfixes libxi libxinerama libxkbcommon libxrandr libxrender lz4 mesa nettle nspr nss pango pcre pixman systemd-libs util-linux-libs wayland xz zlib zstd)

_mirror='https://deb.termius.com'
# I got the URL to download the deb package using the server from ubuntu, path: /var/lib/apt/lists/deb.termius.com_dists_squeeze_main_binary-amd64_Packages
# TERMS_OF_USE is a copy-paste of https://termius.com/terms-of-use from browser
source=(
        "pkgs-$pkgver.gz::$_mirror/dists/squeeze/main/binary-amd64/Packages.gz"
        "$pkgname-$pkgver.deb::https://termius.com/download/linux/Termius.deb"
        "TERMS_OF_USE"
)
sha512sums=(
        "2bc5ee77126fc81955cb596bb1d52d0b6b6cc7b0f1b052043cf99fd2c4527ce735a2b9bf14dd95e3e77b8a2a197069f67bbd433cd1a04f49ccac9451a352823f"
        "af6d8ebe360d9c71d02c11a2b0ecf62226f9c2a2a55a30a2b368b73bcbc38066f88ad7d6600e72c93f0c470cb10438beeb037c7d7bb6a37d83899193dc0fd151"
        'bf187f1ec9387d9c3ddbd0e401a235ec9bafab14698f49a182546ed4a057c398f3532f472b2a6be22b9a200b29d1ccb6e3c2fb69a92dfce2a4bf29264617565b'
)

pkgver() {
        sed -n '/Package: termius-app$/,/^$/p' "$srcdir/pkgs-$pkgver" | grep -o 'Version: .*' | cut -d " " -f 2
}
prepare() {
        mkdir "$srcdir/work" || :
        sha512sum1="$(sha512sum "$srcdir/$pkgname-$pkgver.deb" | cut -d " " -f 1)"
        sha512sum2="$(sed -n '/Package: termius-app$/,/^$/p' "$srcdir/pkgs-$pkgver" | grep -o 'SHA512: .*' | cut -d " " -f 2)"
        if [ "$sha512sum1" != "$sha512sum2" ]; then
                warning "SHA512SUM doesn't match!"
                exit 1
        fi
        bsdtar -x -f "$srcdir"/data.tar.xz -C "$srcdir/work" || :
}

package() {
        cd "$srcdir/work"
        cp -ax ./usr "$pkgdir"/usr
        install -d -m 755 "$pkgdir"/usr/bin
        cp -ax ./opt "$pkgdir"/opt
        ln -s /opt/Termius/$pkgname "$pkgdir"/usr/bin/$pkgname
        ln -s $pkgname "$pkgdir"/usr/bin/$_pkgname
        chmod 4755 /opt/Termius/chrome-sandbox
        sed 's/\/opt\/Termius\/termius-app/\/usr\/bin\/termius/g' -i "$pkgdir"/usr/share/applications/$pkgname.desktop
        install -D -m 644 "$srcdir"/TERMS_OF_USE "$pkgdir"/usr/share/licenses/$_pkgname/TERMS_OF_USE
}