blob: 1c8c29b2a53655047bfbc3b725349846a8fcb9de (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# Maintainer: willemw <willemw12@gmail.com>
pkgname=termusic-git
pkgver=0.6.5.r626.78dfd9b
pkgrel=1
pkgdesc="Terminal Music Player written in Rust"
arch=('x86_64')
url="https://github.com/tramhao/termusic"
license=('GPL3' 'MIT')
depends=('dbus' 'gst-libav' 'gst-plugins-bad' 'gst-plugins-base' 'gst-plugins-good' 'gst-plugins-ugly' 'gstreamer' 'mpv') # 'libmpv.so'
makedepends=('cargo' 'git')
optdepends=('ffmpeg: extract audio by downloader' 'ueberzug: display album covers' 'youtube-dl: download files' 'yt-dlp: download files')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=("$pkgname::git+$url.git")
sha256sums=('SKIP')
pkgver() {
cd $pkgname
printf "%s.r%s.%s" "$(sed -n 's/^version = "\(.*\)"/\1/p' Cargo.toml)" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
RUSTUP_TOOLCHAIN=stable cargo build --release --all-features --manifest-path=$pkgname/Cargo.toml --target-dir=target
}
#check() {
# RUSTUP_TOOLCHAIN=stable cargo test --release --manifest-path=$pkgname/Cargo.toml --target-dir=target
#}
package() {
install -Dm755 "target/release/${pkgname%-git}" -t "$pkgdir/usr/bin"
install -Dm644 $pkgname/LICENSE_MIT -t "$pkgdir/usr/share/licenses/${pkgname%-git}"
mkdir -p "$pkgdir/usr/share/${pkgname%-git}"
cp -a $pkgname/themes "$pkgdir/usr/share/${pkgname%-git}"
}
|