blob: f52d0128744e1c3d07c6cc088011871ed084a9e1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
# Maintainer: Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
pkgname="termux-elf-cleaner"
pkgver=3.0.1
pkgrel=3
pkgdesc="Utility to remove unused ELF sections causing warnings"
arch=(
'aarch64'
'armv7h'
'i686'
'x86_64'
)
url="https://github.com/termux/${pkgname}"
license=(
'GPL-3.0-or-later'
)
depends=(
'glibc'
'libgcc'
'libstdc++'
)
makedepends=(
'cmake>=3.25'
'git'
)
_pkgsrc="${url##*/}"
source=(
"${_pkgsrc}::git+${url}.git#tag=v${pkgver}?signed"
)
sha256sums=('182e1988326907c62b9b5d765d9303882e15fea5eaa940157f8e4c83c8f9ba5a')
validpgpkeys=(
'2C7F29AE97891F6419A9E2CDB0076E490B71616B' # Henrik Grimler <grimler@termux.org>
)
build() {
local cmake_arguments=(
-G 'Unix Makefiles'
-W no-dev
-D CMAKE_BUILD_TYPE:STRING='None'
-D CMAKE_INSTALL_PREFIX:PATH='/usr'
)
cd "${srcdir}"
cmake -B "${_pkgsrc}/build" -S "${_pkgsrc}" "${cmake_arguments[@]}"
cmake --build "${_pkgsrc}/build"
}
check() {
local ctest_exclude_regex="dynamic-section-*"
local ctest_arguments=(
--output-on-failure
--parallel "$(nproc)"
--exclude-regex "${ctest_exclude_regex}"
)
cd "${srcdir}"
ctest --test-dir "${_pkgsrc}/build" "${ctest_arguments[@]}"
}
package() {
cd "${srcdir}"
DESTDIR="${pkgdir}" cmake --install "${_pkgsrc}/build"
cd "${_pkgsrc}"
install -vDm644 "README.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
install -vDm644 "COPYING" "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
}
|