blob: cf6f3f0c58a43c52f77c5d8f4c81a4a9fadcaefd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: Stefan Husmann <stefan-husmann@t-online.de>
pkgname=texinfo-git
pkgver=r8432.34b30bd643
pkgrel=1
pkgdesc="GNU documentation system for on-line information and printed output"
arch=('i686' 'x86_64')
url="http://www.gnu.org/software/texinfo/"
license=('GPL')
groups=('base' 'base-devel')
depends=('coreutils')
makedepends=('git' 'help2man')
provides=('texinfo' 'texinfo-js')
conflicts=('texinfo' 'texinfo-js')
source=("$pkgname::git://git.savannah.gnu.org/texinfo.git"
texinfo-install.hook::https://git.archlinux.org/svntogit/packages.git/plain/trunk/texinfo-install.hook?h=packages/texinfo
texinfo-remove.hook::https://git.archlinux.org/svntogit/packages.git/plain/trunk/texinfo-remove.hook?h=packages/texinfo)
sha256sums=('SKIP'
'66ab7eab5ecdd7757081a743f94e6f4d2e783b61db5024344450748bf1bf8eb9'
'7300f03ac56e32564fb508b0dd07839d2428a422dcf13fd3246863f7ccb1965e')
options=('!makeflags' 'libtool')
pkgver() {
cd $pkgname
printf "r%s.%s" $(git rev-list --count HEAD) $(git describe --always)
}
build() {
export LANG=C
cd $pkgname
./autogen.sh
./configure --prefix=/usr --libexecdir=/usr/lib
make
cd js
aclocal -I gnulib/m4
automake --add-missing
autoreconf -f
./configure --prefix=/usr
make
}
package() {
cd $pkgname
make DESTDIR="$pkgdir/" install
cd js
make DESTDIR="$pkgdir/" install
install -dm755 "$pkgdir"/usr/share/libalpm/hooks/
cd "$srcdir"
install -m644 texinfo-{install,remove}.hook \
"$pkgdir"/usr/share/libalpm/hooks/
}
|