blob: 8ba912623c2d3ff09e75280440a5227b671d1b85 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
_pkgname=texmacs
pkgname=${_pkgname}-qt
pkgver=2.1.1
pkgrel=1
pkgdesc="WYSIWYG free scientific text editor and graphical frontend to various CASes \n
(Giac, GTybalt, Macaulay 2, Maxima, Octave, Pari, Qcl, R and Yacas)"
arch=('x86_64')
url='http://texmacs.org/'
license=('GPL3')
depends=('qt5-base' 'guile1.8' 'libtool' 'perl' 'python')
optdepends=(
'texlive-core: TeX-fonts' # highly recommended, but optional: http://www.texmacs.org/tmweb/download/packaging.en.html
'gawk: conversion of some files'
'ghostscript: rendering ps files'
'imagemagick: convert images'
'aspell: spell checking')
makedepends=('ghostscript' 'cmake' 'cairo' 'imlib2')
options=('!emptydirs')
source=("http://www.texmacs.org/Download/ftp/tmftp/source/TeXmacs-$pkgver-src.tar.gz"
'http://www.texmacs.org/Images/tm_gnu1b.png'
'texmacs.desktop')
sha256sums=('918ca184aca0cb5335906a6c471a1ae3a80c47ab26b5d1c059f0dfcbd906e830'
'f11123275494718a3064c9c3ed9638bcc86402536cdcc875a1dd3c0196d08102'
'0719f63ac6db6fffd979dba77a4ab8f9a8f21bcfef84ed5f425e709eb4bd503e')
build() {
cd TeXmacs-${pkgver}-src
[ -d build ] && rm -rv build
mkdir -p build
cd build
msg "### cmake"
cmake .. \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DGUILECONFIG_EXECUTABLE=/usr/bin/guile-config1.8
msg "### make"
make
}
package() {
cd TeXmacs-${pkgver}-src/build
msg "### make install"
make DESTDIR=${pkgdir} install
sed -i 's|${prefix}|/usr|' "${pkgdir}/usr/bin/fig2ps"
sed -e 's|\@CONFIG_LIB_PATH\@|LD_LIBRARY_PATH|g' -i "$pkgdir"/usr/bin/texmacs
cd ..
_appdir=${pkgdir}/usr/share/applications
_pngdir=${pkgdir}/usr/share/pixmaps
_docdir=${pkgdir}/usr/share/doc/${pkgname}
_licdir=${pkgdir}/usr/share/licenses/${pkgname}
install -dm 755 ${_appdir} ${_pngdir} ${_docdir} ${_licdir}
install -Dpm 0644 ${srcdir}/texmacs.desktop ${_appdir}/
install -Dpm 0644 ${srcdir}/tm_gnu1b.png ${_pngdir}/texmacs.png
install -Dpm 0644 COMPILE COPYING LICENSE TODO TeXmacs/INSTALL TeXmacs/README TeXmacs/TEX_FONTS ${_docdir}/
cd ${_licdir} ; ln -s ../../TeXmacs/LICENSE .
}
|