PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

# Maintainer: Carl Smedstad <carsme@archlinux.org>

pkgname=texttest
pkgver=4.4.5
_commit=5c69626ecf1491f431eb9874b84e0cd700d7eef9
pkgrel=1
pkgdesc="A tool for text-based functional testing"
arch=(any)
url="https://github.com/texttest/texttest"
license=(LGPL-2.1-or-later)
depends=(
  gdk-pixbuf2
  glib2
  gtk3
  pango
  python
  python-certifi
  python-gobject
  python-matplotlib
  python-pillow
  python-psutil
)
makedepends=(
  python-build
  python-installer
  python-setuptools
  python-wheel
)
optdepends=('python-boto: for Amazon EC2 support')
source=("$pkgname-$_commit.tar.gz::$url/archive/$_commit.tar.gz")
sha256sums=('61492e34a6a67ecd4128b0b3d88fcb070bf73feb2e8c841901f7cda07d65ab96')

pkgver() {
  cd $pkgname-$_commit
  grep -Po 'version = "\K[^"]+' texttestlib/texttest_version.py
}

build() {
  cd $pkgname-$_commit
  python -m build --wheel --no-isolation
}

package() {
  cd $pkgname-$_commit
  python -m installer --destdir="$pkgdir" dist/*.whl
}