blob: 130bf0d8ed7b5696e22bdc622b70a91299b87992 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Tércio Martins <echo dGVyY2lvd2VuZGVsQGdtYWlsLmNvbQo= | base64 -d>
# Contributor: M.Reynolds <blackboxnetworkproject@gmail.com>
pkgname=thonny
pkgver=4.1.4
pkgrel=1
pkgdesc="Python IDE for beginners"
arch=('any')
url="https://thonny.org"
license=('MIT')
depends=('esptool' 'hicolor-icon-theme' 'mypy' 'python-asttokens' 'python-docutils' \
'python-jedi' 'python-pip' 'python-pylint' 'python-pillow' 'python-ptyprocess' \
'python-send2trash' 'python-setuptools' 'python-wheel' 'tk')
makedepends=('python-build' 'python-installer')
optdepends=('python-birdseye: Debug support with Birdseye'
'python-pgzero: Run programs made with Pygame Zero')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/${pkgname}/${pkgname}/archive/v${pkgver}.tar.gz")
b2sums=('a1dadf4a58dc3e32e48659b1ef12d0d52be2b9f462da5e8ee2bbe8def5c6c4862613e6e0803acc4499149c64309ba38f28aaafc39687b6affb4d67b2f74bff3b')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
python -m build --wheel --no-isolation
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
python -m installer --destdir="$pkgdir" dist/*.whl
_xdg_desktop_name=org.${pkgname}.${pkgname^}
install -Dm 644 "packaging/linux/${_xdg_desktop_name}.desktop" \
"${pkgdir}/usr/share/applications/${_xdg_desktop_name}.desktop"
sed -i "s/Icon=${pkgname}/Icon=${_xdg_desktop_name}/" \
"${pkgdir}/usr/share/applications/${_xdg_desktop_name}.desktop"
install -Dm 644 "packaging/linux/${_xdg_desktop_name}.appdata.xml" \
"${pkgdir}/usr/share/metainfo/${_xdg_desktop_name}.appdata.xml"
for size in 16 22 32 48 64 128 256; do
install -Dm 644 "packaging/icons/${pkgname}-${size}x${size}.png" \
"${pkgdir}/usr/share/icons/hicolor/${size}x${size}/apps/${_xdg_desktop_name}.png"
done
install -Dm 644 "LICENSE.txt" \
"${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|