blob: 15c61db8260bfe5f0d8e0b46ef7aef0ad66eeeca (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Tércio Martins <echo dGVyY2lvd2VuZGVsQGdtYWlsLmNvbQo= | base64 -d>
# Contributor: M.Reynolds <blackboxnetworkproject@gmail.com>
pkgname=thonny
pkgver=4.1.2
pkgrel=1
pkgdesc="Python IDE for beginners"
arch=('any')
url="https://thonny.org"
license=('MIT')
depends=('esptool' 'hicolor-icon-theme' 'mypy' 'python-asttokens' 'python-docutils' \
'python-jedi' 'python-pip' 'python-pylint' 'python-pillow' 'python-ptyprocess' \
'python-send2trash' 'python-setuptools' 'python-wheel' 'tk')
makedepends=('python-build' 'python-installer')
optdepends=('python-birdseye: Debug support with Birdseye'
'python-pgzero: Run programs made with Pygame Zero')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/${pkgname}/${pkgname}/archive/v${pkgver}.tar.gz")
sha512sums=('43401d4ed1a32f996290008b583b49b80eb24fd7df4ac07b9f1d4f28b0fdb4223198cbd6c981844eaba1a6f84f63497c3769710601c0b0c8cad51deb34df51c6')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
python -m build --wheel --no-isolation
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
python -m installer --destdir="$pkgdir" dist/*.whl
_xdg_desktop_name=org.${pkgname}.${pkgname^}
install -Dm 644 "packaging/linux/${_xdg_desktop_name}.desktop" \
"${pkgdir}/usr/share/applications/${_xdg_desktop_name}.desktop"
sed -i "s/Icon=${pkgname}/Icon=${_xdg_desktop_name}/" \
"${pkgdir}/usr/share/applications/${_xdg_desktop_name}.desktop"
install -Dm 644 "packaging/linux/${_xdg_desktop_name}.appdata.xml" \
"${pkgdir}/usr/share/metainfo/${_xdg_desktop_name}.appdata.xml"
for size in 16 22 32 48 64 128 256; do
install -Dm 644 "packaging/icons/${pkgname}-${size}x${size}.png" \
"${pkgdir}/usr/share/icons/hicolor/${size}x${size}/apps/${_xdg_desktop_name}.png"
done
install -Dm 644 "LICENSE.txt" \
"${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|