blob: f74bd1050bb5105e39648f8078ff11f239a0da58 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Tércio Martins <echo dGVyY2lvd2VuZGVsQGdtYWlsLmNvbQo= | base64 -d>
# Contributor: M.Reynolds <blackboxnetworkproject@gmail.com>
pkgname=thonny
pkgver=3.3.3
pkgrel=1
pkgdesc="Python IDE for beginners"
arch=('any')
url="https://thonny.org"
license=('MIT')
depends=('hicolor-icon-theme' 'mypy' 'python-astroid' 'python-asttokens' 'python-docutils' 'python-jedi' \
'python-pylint' 'python-pyserial' 'python-send2trash' 'python-setuptools' 'tk')
optdepends=('python-birdseye: Debug support with Birdseye')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/${pkgname}/${pkgname}/archive/v${pkgver}.tar.gz")
sha512sums=('46abda75ad351601ac4d7abf148d5281f47406c5991c8b9b0a48aab5574c46fd09654e639bb806d13c32793d7b7371a145468bdd24f2bacc535feac321ed297d')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
python setup.py build
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
python setup.py install --root="$pkgdir" --optimize=1 --skip-build
_xdg_desktop_name=org.${pkgname}.${pkgname^}
install -Dm 644 "packaging/linux/${_xdg_desktop_name}.desktop" \
"${pkgdir}/usr/share/applications/${_xdg_desktop_name}.desktop"
sed -i "s/Icon=${pkgname}/Icon=${_xdg_desktop_name}/" \
"${pkgdir}/usr/share/applications/${_xdg_desktop_name}.desktop"
install -Dm 644 "packaging/linux/${_xdg_desktop_name}.appdata.xml" \
"${pkgdir}/usr/share/metainfo/${_xdg_desktop_name}.appdata.xml"
for size in 16 22 32 48 64 128 256; do
install -Dm 644 "packaging/icons/${pkgname}-${size}x${size}.png" \
"${pkgdir}/usr/share/icons/hicolor/${size}x${size}/apps/${_xdg_desktop_name}.png"
done
install -Dm 644 "LICENSE.txt" \
"${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|