blob: b6f28cdc86a0121a7c84864808c7d29171de5ca6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# Maintainer: Alad Wenter <nynq@nepuyvahk.vasb> (rot13)
# Contributor: Limao Luo <luolimao+AUR@gmail.com>
# Contributor: Evangelos Foutras <evangelos@foutrelis.com>
# Contributor: Andrew Simmons <andrew.simmons@gmail.com>
pkgname=thunar-git
pkgver=1.6.12.r96.g9d9ed111
pkgrel=1
pkgdesc='file manager for xfce'
arch=('i686' 'x86_64')
license=('GPL')
url='http://thunar.xfce.org'
groups=('xfce4-git')
depends=('desktop-file-utils' 'exo' 'gtk3' 'hicolor-icon-theme' 'libgudev'
'libexif' 'libnotify' 'libpng' 'libxfce4ui' 'libxfce4util')
makedepends=('git' 'xfce4-dev-tools')
optdepends=('gvfs: trash support, mounting with udisks, and remote filesystems'
'xfce4-panel: trash applet'
'tumbler: for thumbnail previews'
'thunar-volman: manages removable devices'
'thunar-archive-plugin: create and deflate archives'
'thunar-media-tags-plugin: view/edit id3/ogg tags')
provides=("thunar=${pkgver%%.r*}")
conflicts=('thunar')
source=("$pkgname::git+https://git.xfce.org/xfce/thunar")
sha256sums=('SKIP')
pkgver() {
cd "$pkgname"
git describe --long | sed -e 's/^thunar.//' -e 's/\([^-]*-g\)/r\1/' -e 's/-/./g'
}
prepare() {
cd "$pkgname"
./autogen.sh \
--prefix=/usr \
--sysconfdir=/etc \
--libexecdir=/usr/lib \
--localstatedir=/var \
--disable-static \
--enable-gio-unix \
--enable-dbus \
--enable-startup-notification \
--enable-gudev \
--enable-exif \
--enable-pcre \
--enable-gtk-doc \
--disable-debug
}
build() {
cd "$pkgname"
make
}
package() {
cd "$pkgname"
make DESTDIR="$pkgdir" install
}
|