PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57

# Maintainer: Darius Niminenn <root@dnim.dev>

pkgname=tidal-dl-ng
_pkgname=${pkgname//-/_}
pkgver=0.13.2
pkgrel=1
pkgdesc='A tool for downloading music and albums from TIDAL'
arch=(any)
url='https://pypi.org/project/tidal-dl-ng/'
license=(AGPL-3.0-only)
depends=(
    'python>=3.10'
    'python-requests'
    'python-mutagen'
    'python-pycryptodome'
    'python-tidalapi'
    'python-dataclasses-json'
    'python-pathvalidate'
    'python-m3u8'
    'python-coloredlogs'
    'python-rich'
    'python-toml'
    'python-typer'
    'python-ffmpeg-python'
    'pyside6'
    'python-pyqtdarktheme'
)
makedepends=(
    'python-poetry-core'
)
source=(
    "https://files.pythonhosted.org/packages/source/t/$_pkgname/$_pkgname-$pkgver.tar.gz"
    "tidal-dl-ng"
    "tidal-dl-ng-gui"
)
sha256sums=('08c6bd354b994071f8e8398234319316c65e59a8620933e8cfa67e56d7c5995f'
            '1d2f9b06b7bba762f9a8770b163e001e5044a38b9d5befa8ea44fa3c98bcf172'
            'ecdc2868d0df9fa41e3bca50f3f0bcfede7543b54700f45b2095b9662da6dd9c')

prepare() {
    cd "$_pkgname-$pkgver"
    rm -rf dist
}

build() {
    cd "$_pkgname-$pkgver"
    python -m build --wheel --no-isolation
}

package() {
    cd "$_pkgname-$pkgver"
    python -m installer --destdir="$pkgdir" dist/*.whl

    # Install scripts
    install -Dm755 "${srcdir}/tidal-dl-ng" "${pkgdir}/usr/bin/tidal-dl-ng"
    install -Dm755 "${srcdir}/tidal-dl-ng-gui" "${pkgdir}/usr/bin/tidal-dl-ng-gui"
}