PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

# Maintainer: Batou <batou at cryptolab dot net>
pkgname=tifig-git
pkgver=r73.7dea067
pkgrel=1
pkgdesc="A fast High Efficiency Image File Format (HEIF/HEIC) converter"
arch=('x86_64')
url="https://github.com/monostream/tifig"
license=('Apache')
depends=('ffmpeg' 'vips')
makedepends=('git' 'cmake')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=(
	'git+https://github.com/monostream/tifig.git'
	'git+https://github.com/monostream/heif.git'
	'git+https://github.com/jarro2783/cxxopts.git'
)
md5sums=(
	'SKIP'
	'SKIP'
	'SKIP'
)

pkgver() {
	cd "$srcdir/${pkgname%-git}"
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  cd "$srcdir/${pkgname%-git}"
  local submodules=(
    'lib/heif'
    'lib/cxxopts'
  )
  for submodule in "${submodules[@]}"; do
    git submodule init "$submodule"
    git config "submodule.$submodule.url" "$srcdir/${submodule##*/}"
    git submodule update "$submodule"
  done
}

build() {
	cd "$srcdir/${pkgname%-git}"
	mkdir -p "build" && cd "build"
	cmake ..
	make
}

package() {
	cd "$srcdir/${pkgname%-git}/build"
	install -Dm755 "${pkgname%-git}" "${pkgdir}/usr/bin/${pkgname%-git}"
}