blob: 859d0ab735004059cf22977fa417dd319008b231 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Davi da Silva Böger <dsboger at gmail dot com>
pkgname=tilix-git
_pkgname=tilix
pkgver=1.5.4.r8.bba5320
pkgrel=1
pkgdesc="A tiling terminal emulator based on GTK+ 3 (git master)"
arch=('x86_64' 'i686')
url="http://github.com/gnunn1/tilix"
license=('MPL')
depends=('libx11' 'gtkd' 'vte3' 'dconf' 'gsettings-desktop-schemas')
optdepends=('python2-nautilus: for "Open Tilix Here" support in nautilus'\
'vte3-notification: for desktop notifications support'\
'vte3-terminix-git: for notifications, triggers and badges support'
'libsecret: for the password manager')
makedepends=('git' 'ldc')
provides=('terminix' 'tilix')
conflicts=('terminix' 'tilix')
source=('git+https://github.com/gnunn1/tilix')
sha512sums=('SKIP')
pkgver() {
cd ${_pkgname}
# sed transformation explained:
# s/^v// - removes the leading "v" from the tag name, if any (tilix doesn't use it, but harmless)
# s/\([^-]*-\)g/r\1/ - replaces the "g" that precedes the commit hash with "r"
# s/-/./g - replaces all the remaining "-" with "."
git describe --long --tags | sed 's/^v//;s/\([^-]*-\)g/r\1/;s/-/./g'
}
prepare() {
cd ${_pkgname}
chmod u+x autogen.sh
./autogen.sh
}
build() {
cd ${_pkgname}
./configure --prefix=/usr
make DC='ldmd' DCFLAGS='-O -inline -release -version=StdLoggerDisableTrace'
}
package() {
cd ${_pkgname}
make DESTDIR=${pkgdir} install
}
|