blob: 4561396d896625e08670656d304323d675b1137b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: Mark Wagie <mark dot wagie at tutanota dot com>
# Contributor: Igor <f2404@yandex.ru>
# Contributor: Davi da Silva Böger <dsboger at gmail dot com>
pkgname=tilix-git
pkgver=1.9.5.r33.gee1e65ac
pkgrel=1
pkgdesc="A tiling terminal emulator for Linux using GTK+ 3"
arch=('x86_64')
url="https://gnunn1.github.io/tilix-web"
license=('MPL2')
depends=('libx11' 'gtkd' 'vte3' 'dconf' 'gsettings-desktop-schemas')
makedepends=('appstream' 'git' 'ldc' 'po4a' 'meson')
checkdepends=('appstream-glib')
optdepends=('python-nautilus: for "Open Tilix Here" support in nautilus'
'libsecret: for the password manager'
'vte3-notification: for desktop notifications support')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
options=('!lto')
source=('git+https://github.com/gnunn1/tilix.git'
'update-to-gtkd-3.10.0.patch')
sha256sums=('SKIP'
'ee3136dfca40ddc9407b94d79d6ad664abee16aa770f161b5d07ae50293820c6')
pkgver() {
cd "$srcdir/${pkgname%-git}"
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "$srcdir/${pkgname%-git}"
# Update to GtkD 3.10.0
# https://github.com/gnunn1/tilix/pull/2100
patch -Np1 -i ../update-to-gtkd-3.10.0.patch
}
build() {
# Build with LDC
export DC=ldc
export LDFLAGS="$(echo -ne $LDFLAGS | sed -e 's/-flto=auto/-flto=full/')"
arch-meson "${pkgname%-git}" build
meson compile -C build
}
check() {
meson test -C build --print-errorlogs
appstream-util validate-relax --nonet build/data/com.gexperts.Tilix.appdata.xml
}
package() {
meson install -C build --destdir "$pkgdir"
}
|