blob: be0b6d2aef81e4d63d76f499eaf993fa4f8eebe8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=tinyssh-git
pkgver=20230101.r1.g40e0fe7
pkgrel=3
pkgdesc="Minimalistic SSH server"
arch=('i686' 'x86_64')
url="https://tinyssh.org/"
license=('custom:Public Domain')
depends=('glibc')
makedepends=('git')
provides=("tinyssh=$pkgver")
conflicts=('tinyssh')
source=("git+https://github.com/janmojzis/tinyssh.git"
"tinyssh@.service::https://gitlab.archlinux.org/archlinux/packaging/packages/tinyssh/-/raw/main/tinyssh@.service"
"tinyssh@.socket::https://gitlab.archlinux.org/archlinux/packaging/packages/tinyssh/-/raw/main/tinyssh@.socket"
"tinysshgenkeys.service::https://gitlab.archlinux.org/archlinux/packaging/packages/tinyssh/-/raw/main/tinysshgenkeys.service")
sha256sums=('SKIP'
'SKIP'
'SKIP'
'SKIP')
prepare() {
cd "tinyssh"
echo "/usr/bin" > "conf-bin"
}
pkgver() {
cd "tinyssh"
_tag=$(git tag -l --sort -v:refname | grep -E '^v?[0-9\.]+$' | head -n1)
_rev=$(git rev-list --count $_tag..HEAD)
_hash=$(git rev-parse --short HEAD)
printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/^v//'
}
build() {
cd "tinyssh"
make
}
package() {
cd "tinyssh"
make DESTDIR="$pkgdir" install
install -d "$pkgdir/etc/tinyssh"
install -Dm644 "$srcdir"/{tinysshgenkeys.service,tinyssh@.service,tinyssh@.socket} \
-t "$pkgdir/usr/lib/systemd/system"
install -Dm644 "LICENCE" -t "$pkgdir/usr/share/licenses/tinyssh"
}
|