blob: a114b47577201eea9a2ea70a7dc79257770457df (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
|
# Maintainer: Juan A. Rubio <jarubio2001@gmail.com>
_githubname=tizonia-openmax-il
pkgname=tizonia-all-git
pkgver=0.9.0.r7.gee2765aa
pkgrel=1
pkgdesc="Command-line cloud music player for Linux with Spotify, Google Play Music, YouTube, SoundCloud, and Dirble support"
arch=('x86_64')
url="https://www.tizonia.org"
license=('LGPL')
depends=(
# official repositories:
'libmad'
'sqlite'
'libutil-linux'
'taglib'
'mediainfo'
'sdl'
'lame'
'faad2'
'libcurl-gnutls'
'libvorbis'
'libvpx'
'mpg123'
'opus'
'opusfile'
'libogg'
'libfishsound'
'flac'
'liboggz'
'libsndfile'
'alsa-lib'
'libpulse'
'boost'
'dbus-c++'
'check'
'python2-pafy'
# AUR:
'log4c'
'libspotify'
'python2-gmusicapi'
'python-soundcloud-git'
'python2-youtube-dl-git'
)
provides=('tizonia-all')
conflicts=('tizonia-all')
source=("${pkgname}"::"git+https://github.com/tizonia/${_githubname}.git")
sha256sums=('SKIP')
pkgver() {
cd "$pkgname"
local _version="$(git tag | sort -Vr | head -n1 | sed 's/^v//')"
local _revision="$(git rev-list v"${_version}"..HEAD --count)"
local _shorthash="$(git rev-parse --short HEAD)"
printf '%s.r%s.g%s' "$_version" "$_revision" "$_shorthash"
}
prepare() {
mkdir -p "$srcdir/path"
# Tizonia expects Python 2
ln -sf /usr/bin/python2 "$srcdir/path/python"
ln -sf /usr/bin/python2-config "$srcdir/path/python-config"
}
build() {
export PATH="$srcdir/path:$PATH"
export PYTHON="/usr/bin/python2"
cd "$pkgname"
autoreconf -ifs
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var \
--silent \
--enable-silent-rules \
CFLAGS='-O2 -s -DNDEBUG' \
CXXFLAGS='-O2 -s -DNDEBUG -fstack-protector --param=ssp-buffer-size=4 -Wformat -Werror=format-security'
make
}
package() {
cd "$pkgname"
make DESTDIR="$pkgdir/" install
}
|