blob: e414145c8014b3903ab2df3d412bfad16b544e87 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer: mutantmonkey <aur@mutantmonkey.in>
# Contributor: skydrome <skydrome@tormail.org>
pkgname=tlsdate-git
pkgver=692.5be06de
pkgrel=1
pkgdesc="A secure rdate replacement to update local time over HTTPS, git version"
arch=('i686' 'x86_64' 'armv6l' 'armv6h' 'arm7l' 'arm7h')
url="https://github.com/ioerror/tlsdate"
license=('BSD')
depends=('openssl' 'ca-certificates' 'dbus' 'zlib')
conflicts=('tlsdate')
provides=('tlsdate')
options=(emptydirs)
install=tlsdate.install
backup=('etc/conf.d/tlsdate'
'etc/tlsdate/tlsdated.conf')
source=('git+https://github.com/ioerror/tlsdate.git'
'tlsdate.conf.d'
'tlsdate.service')
sha256sums=('SKIP'
'1498a74913feb66c6e2e7d982f43b07fc48881947543969668a75ef4323503aa'
'fe3fb8181be0a9214f351c64461680f603ea27b7b7c566c9eec189084783aa92')
pkgver() {
cd "$srcdir/tlsdate"
echo $(git rev-list --count master).$(git rev-parse --short master)
}
prepare() {
cd "$srcdir/tlsdate"
./autogen.sh
}
build() {
cd "$srcdir/tlsdate"
./configure \
--prefix=/usr \
--sbindir=/usr/bin \
--sysconfdir=/etc \
--with-dbus-client-group=tlsdate \
--with-unpriv-group=tlsdate \
--with-unpriv-user=tlsdate \
--without-polarssl
make
}
package() {
cd "$srcdir/tlsdate"
make DESTDIR="$pkgdir" install
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/tlsdate/LICENSE"
install -Dm644 "$srcdir/tlsdate.conf.d" "$pkgdir/etc/conf.d/tlsdate"
install -Dm644 "$srcdir/tlsdate.service" "$pkgdir/usr/lib/systemd/system/tlsdate.service"
}
# vim:set ts=2 sw=2 et:
|