blob: 6334f5b08bb2296305885ef7be45a0a743c050f0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
pkgname=tlstunnel-git
pkgver=r69.a154e708fcbb
pkgrel=3
pkgdesc='A TLS reverse proxy'
arch=('x86_64')
url="https://sr.ht/~emersion/tlstunnel"
license=('MIT')
makedepends=('git' 'go' 'scdoc')
source=(
"$pkgname::git+https://git.sr.ht/~emersion/tlstunnel"
'tlstunnel.service'
'tlstunnel.tmpfiles'
'tlstunnel.sysusers'
)
sha256sums=(
'SKIP'
'a298eb15cef1253c235c89e670a01f2ef9eb09276b0661c7b265cfd8bf43326a'
'4a891acfb64531c8ff3a9b1d596df749614d89dd4edd4571f683b71c7c31a5a6'
'068caae43739c591b84ed36db6545e7c694e17443d86bfdbc6568e49cdde103f'
)
backup=('etc/tlstunnel/config')
pkgver() {
cd "$pkgname"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cd "$pkgname"
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
make GOFLAGS="$GOFLAGS"
}
package() {
cd "$pkgname"
make install PREFIX=/usr DESTDIR="$pkgdir"
install -Dm644 "$srcdir/tlstunnel.service" -t "$pkgdir/usr/lib/systemd/system"
install -Dm644 "$srcdir/tlstunnel.tmpfiles" "$pkgdir/usr/lib/tmpfiles.d/tlstunnel.conf"
install -Dm644 "$srcdir/tlstunnel.sysusers" "$pkgdir/usr/lib/sysusers.d/tlstunnel.conf"
install -Dm644 "/dev/null" "$pkgdir/etc/tlstunnel/config"
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|