PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

# Maintainer: Ruben Agin <phabrics@phabrics.com>
pkgname=tme
pkgver=0.12rc10
pkgrel=1
pkgdesc="The Machine Emulator, or tme, provides a general-purpose framework for computer emulation."
arch=('i686' 'x86_64')
license=('GPL3')
url="http://phabrics.com"
makedepends=('perl-x11-protocol')
depends=('libvncserver' 'gtk4' 'sdl2')
source=("https://osdn.net/dl/nme/${pkgname}-${pkgver}.tar.xz")
sha256sums=('e2c90f7c63de196c7bf52c9b06f17e2ab9db86fa86d8c3ff3ee2360fb20914f8')
options=('libtool')
install=$pkgname.install

prepare()
{
  cd "$pkgname-$pkgver"
  sed -i '/#include "display.h"/i unsigned int _tme_scanline_pad(int bpl);' host/display/display.c
}

build()
{
  cd "$pkgname-$pkgver"
  if test "x${CARCH}" = xx86_64; then
      ./configure --prefix=/usr --disable-ltdl-install --disable-recode
  else
      ./configure --prefix=/usr --disable-ltdl-install
  fi
  make
}

package()
{
  cd "$pkgname-$pkgver"
  make DESTDIR="$pkgdir/" install
}