PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

# Maintainer: Jonas Platte <aur@jonasplatte.de>

pkgname=tntnet-git
pkgver=2.3rc1.r4.g6c10627
pkgrel=1
pkgdesc="A modular, multithreaded, high performance webapplication server for C++"
arch=('i686' 'x86_64')
url="http://www.tntnet.org/tntnet.html"
license=('LGPL')
depends=('cxxtools-git' 'zlib' 'openssl' 'sh')
makedepends=('git')
optdepends=('base-devel: to build tntnet web applications')
provides=('tntnet')
conflicts=('tntnet')
backup=('etc/tntnet/tntnet.xml')
source=("$pkgname::git+https://github.com/maekitalo/${pkgname%-git}.git")
sha256sums=('SKIP')

pkgver() {
  cd "$pkgname"
  git describe --long | sed 's/^V//' | sed 's/-/.r/;s/-/./'
}

build() {
  cd "$pkgname"

  autoreconf -i
  ./configure --enable-silent-rules --prefix=/usr --sysconfdir=/etc
  make
}

# Currently broken
#check() {
#  cd "$pkgname"
#
#  ./test/tntnet-test
#}

package() {
  cd "$pkgname"

  make DESTDIR="$pkgdir/" install
  install -Dm644 ./etc/tntnet/tntnet.xml "$pkgdir/etc/tntnet/tntnet.xml"
}