blob: 4830e10f200237395060547c4d29848ea4288746 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Maintainer: Kuba Serafinowski <zizzfizzix(at)gmail(dot)com>
# https://github.com/zizzfizzix/pkgbuilds
# Maintainer: Solomon Choina <shlomochoina(at)gmail(dot)com>
##############################################################
#### The section below can be adjusted to suit your needs ####
##############################################################
# What type of build do you want?
# See http://techbase.kde.org/Development/CMake/Addons_for_KDE#Buildtypes to check what is supported.
_buildtype='Release'
##############################################################
pkgname=tomahawk-git
pkgver=0.8.0rc1.1304.g119a7ebdb
pkgrel=1
epoch=1
pkgdesc='A Music Player App written in C++/Qt - development version'
arch=('i686' 'x86_64')
url='http://tomahawk-player.org/'
license=('GPL3')
depends=('qt5-svg' 'qt5-tools' 'qt5-xmlpatterns' 'qt5-x11extras' 'qca-qt5'
'taglib' 'lucene++' 'libechonest' 'jreen'
'quazip' 'attica-qt5' 'qt5-webkit' 'liblastfm-qt5'
'qtkeychain' 'vlc')
makedepends=('git' 'cmake' 'extra-cmake-modules' 'sparsehash' 'boost')
optdepends=('kdelibs: integration with Plasma Desktop' 'telepathy-qt5: integration with Telepathy')
provides=('tomahawk')
conflicts=('tomahawk' 'tomahawk-qt5')
source=("${pkgname}::git://github.com/tomahawk-player/tomahawk.git"
"fix-qt5-dependencies.patch")
sha256sums=('SKIP'
'7dba918658edcec661760ac7d33d18bf8fbbdd507b60139e858d027492bec4cb')
if [[ ! ${_buildtype} == 'Release' ]] && [[ ! ${_buildtype} == 'release' ]]; then
options=('debug')
fi
pkgver() {
cd "${srcdir}/${pkgname}"
git describe --always --tags | sed 's|-|.|g'
}
prepare() {
cd "${srcdir}/${pkgname}"
patch -p0 -i ../fix-qt5-dependencies.patch
}
build() {
cd "${srcdir}/${pkgname}"
# Hatchet is dead and causes build error with newer versions of websocketpp,
# so disable it. See <https://github.com/tomahawk-player/tomahawk/issues/654>
cmake -DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_INSTALL_LIBDIR=lib \
-DCMAKE_INSTALL_LIBEXECDIR=lib/tomahawk \
-DBUILD_HATCHET=OFF \
-DCMAKE_BUILD_TYPE=${_buildtype}
make
}
package() {
cd "${srcdir}/${pkgname}"
make DESTDIR="${pkgdir}" install
}
|