PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53

# Maintainer: Markus Hoffmann

pkgname=tone3000-bin
pkgver=0.0.12
pkgrel=1
pkgdesc='Standalone and audio plug-ins for playing Neural Amp Modeler captures and impulse responses'
arch=('x86_64')
url='https://github.com/tone-3000/tone3000-plugin'
license=('MIT')
options=('!debug')
depends=('alsa-lib' 'curl' 'fontconfig' 'freetype2' 'gtk3' 'libx11' 'webkit2gtk-4.1')
optdepends=('jack2: JACK audio backend for the standalone application')
provides=('tone3000-clap' 'tone3000-lv2' 'tone3000-vst3')
source=(
  "${pkgname}-${pkgver}-linux-x64.tar.gz::https://github.com/tone-3000/tone3000-plugin/releases/download/v${pkgver}/TONE3000-v${pkgver}-linux-x64.tar.gz"
  "LICENSE::https://raw.githubusercontent.com/tone-3000/tone3000-plugin/v${pkgver}/LICENSE"
)
sha256sums=(
  'c45ea5d64e6eef991b14f1883a4249ed1a883253db1a9d9f0605e0540aba5fc7'
  '88d4908d7343898f682e47e70f4288728006ed650dbf79e8940c709d55b76326'
)

package() {
  local _src="${srcdir}/TONE3000-v${pkgver}-linux-x64"

  install -Dm755 "${_src}/TONE3000" "${pkgdir}/usr/bin/TONE3000"
  install -Dm644 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  install -Dm644 "${_src}/TONE3000.clap" "${pkgdir}/usr/lib/clap/TONE3000.clap"
  install -Dm644 "${_src}/tone3000.png" \
    "${pkgdir}/usr/share/icons/hicolor/512x512/apps/tone3000.png"

  install -d "${pkgdir}/usr/lib/lv2"
  cp -r "${_src}/TONE3000.lv2" "${pkgdir}/usr/lib/lv2/"

  install -d "${pkgdir}/usr/lib/vst3"
  cp -r "${_src}/TONE3000.vst3" "${pkgdir}/usr/lib/vst3/"

  install -d "${pkgdir}/usr/share/TONE3000/Presets/Factory"
  install -m644 "${_src}"/factory-presets/*.t3kpreset \
    "${pkgdir}/usr/share/TONE3000/Presets/Factory/"

  install -Dm644 /dev/stdin "${pkgdir}/usr/share/applications/tone3000.desktop" <<'EOF'
[Desktop Entry]
Type=Application
Name=TONE3000
Comment=Play NAM captures and impulse responses
Exec=TONE3000
Icon=tone3000
Terminal=false
Categories=AudioVideo;Audio;Music;
StartupWMClass=TONE3000
EOF
}