summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 12d02ba360c493e2154642332b0a110096903aea (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
# Maintainer: Yardena Cohen <yardenack at gmail dot com>
# Contributor: Max Roder <maxroder@web.de>
# Contributor: Sebastian Jug <seb AT stianj DOT ug>
# Contributor: midgard <arch dot midgard "at symbol" janmaes "youknowwhat" com>

# To port this PKGBUILD to another language of tor-browser you
# have to change $pkgname, $_language, $pkgdesc and $url in PKGBUILD
# AND (!) the first line in the .install file!

pkgname='tor-browser-en'
pkgver='7.5.6'
_language='en-US'
pkgrel=1
pkgdesc='Tor Browser Bundle: anonymous browsing using Firefox and Tor'
url='https://www.torproject.org/projects/torbrowser.html.en'
arch=('x86_64')
license=('GPL')
depends=('gtk2' 'mozilla-common' 'libxt' 'startup-notification' 'mime-types'
         'dbus-glib' 'alsa-lib' 'desktop-file-utils' 'hicolor-icon-theme'
         'libvpx' 'icu' 'libevent' 'nss' 'hunspell' 'sqlite')
optdepends=('zenity: simple dialog boxes'
            'kdialog: KDE dialog boxes'
            'gst-plugins-good: H.264 video'
            'gst-libav: H.264 video'
            'libpulse: PulseAudio audio driver'
            'libnotify: Gnome dialog boxes')
install="${pkgname}.install"
validpgpkeys=('EF6E286DDA85EA2A4BA7DE684E2C6E8793298290')
source=("https://dist.torproject.org/torbrowser/${pkgver}/tor-browser-linux64-${pkgver}_${_language}.tar.xz"{,.asc}
        "${pkgname}.desktop"
        "${pkgname}.png"
        "${pkgname}.sh")
md5sums=('bf27ff41397044ec4d5c4cfb0e486f4c'
         'SKIP'
         '69c75e328c117249b30a757f60b634bf'
         '7cd059a3b8194745d7d458a628ccc43a'
         '8fdd23d758c49ba83eba1b01d1934924')
sha256sums=('bafcde14e53987a7df17f88d69f5aec4bd65312720df931080cae7e8caa3e71f'
            'SKIP'
            '5a3c8dc36f46b22a2bc45de6209d5efa14898e24d968cd08a7e0e767ea3259bd'
            'bb6b0f27c33d21e0ef6df961e25418327c5e8b01c003bbe18c0a8dae3e16d77d'
            'b51ca669753409c647ba2582b3eb866b409eca61c216f879ed3c1aded8463526')
sha512sums=('4697d82157321c2a15521e11f39953924336d29e9eb376931a0047a3060007715f3c29c568d592271a4d3ff090e9d20d82c295fad4f7579b9a3b51f48d476650'
            'SKIP'
            '1318a652f7b65e30cdb0c607faf4391035288bcfcaffc50f7713de8eeb7d9151c115269fad1225fccd71d4d38537a804f05fba03b3df516afbce8a79d8988d7c'
            '89d971f4f0db7d1b50e090040ddce0f7191d511f4c1cae9d2c3364fda40a43b7f506d0c015ddd1485304fadbc0bf7d5d61d1dbc12bf645a7e615f51c1d1261e0'
            '88c5d3035df46aa23cd98657e19b907a68ac233f92307556ea44b6a90bac2d04dfb5b23c7efaa3addd48a5def3daacf0c8731acb59b15a7390c4c3435427674a')
noextract=("tor-browser-linux64-${pkgver}_${_language}.tar.xz")

prepare() {
   # We search and replace using sed with / as delimiter below so we can't allow slashes in these vars.
   # Makepkg already enforces that there're no slashes in $pkgname, so we don't check that again here.
   if [[ $pkgver = */* || $_language = */* || $pkgdesc = */* ]]; then
      error '$pkgver, $_language and $pkgdesc for this package are not allowed to contain /' >&2
      return 1
   fi
}

package() {
   cd "${srcdir}"

   sed -i "s/REPL_NAME/${pkgname}/g"       "${pkgname}.sh"
   sed -i "s/REPL_VERSION/${pkgver}/g"     "${pkgname}.sh"
   sed -i "s/REPL_LANGUAGE/${_language}/g" "${pkgname}.sh"

   sed -i "s/REPL_NAME/${pkgname}/g"       "${pkgname}.desktop"
   sed -i "s/REPL_LANGUAGE/${_language}/g" "${pkgname}.desktop"
   sed -i "s/REPL_COMMENT/${pkgdesc}/g"    "${pkgname}.desktop"

   install -Dm 644 "${pkgname}.desktop"    "${pkgdir}/usr/share/applications/${pkgname}.desktop"
   install -Dm 644 "${pkgname}.png"        "${pkgdir}/usr/share/pixmaps/${pkgname}.png"
   install -Dm 755 "${pkgname}.sh"         "${pkgdir}/usr/bin/${pkgname}"

   install -Dm 644 "tor-browser-linux64-${pkgver}_${_language}.tar.xz" "${pkgdir}/opt/${pkgname}/tor-browser-linux64-${pkgver}_${_language}.tar.xz"
}

# vim: set et ts=3 sw=3 :