blob: d958b94e62177eedd6b6a3b847e2fd9408814b15 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
|
# Contributor: skydrome <skydrome@i2pmail.org>
# Maintainer: skydrome <skydrome@i2pmail.org>
pkgname=tor-git
_branch=master
#_branch=maint-0.3.5
pkgver=0.4.0.0.alpha.30808
pkgrel=1
pkgdesc="An anonymizing overlay network (development version)"
arch=('i686' 'x86_64' 'armv6h' 'armv7h')
url="http://www.torproject.org"
license=('BSD')
depends=('openssl' 'libevent' 'libseccomp' 'zstd')
makedepends=('asciidoc')
optdepends=('torsocks: for torify support')
conflicts=('tor')
provides=('tor')
install='tor.install'
backup=('etc/tor/torrc')
source=("git+https://git.torproject.org/tor.git#branch=${_branch}"
#"git+https://github.com/torproject/tor.git#branch=${_branch}"
'torrc'
'tor.service' 'tor.tmpfiles' 'tor.sysusers')
sha256sums=('SKIP'
'413bc43b5c51ff1672b426034598c1d47d5fb94474762cda06668cb28ca9250d'
'3fbea6b96d3ef86836c089da0c9c3d3263db133f3203c5e58b25f0dcaf03f8bf'
'07bedb17660a3673b31b0005b6505065c90b32f2c6b28b969241da675560f926'
'4282c8a4f1471b3be345b2024491af89f5eeaac071884f2a55988aef94a2054b')
pkgver () {
cd "$srcdir/tor"
echo "$(grep AC_INIT configure.ac \
| sed 's/.*\[\(.*\)\].*/\1/;s/-/./g;s/.dev//').$(git rev-list --count origin/$_branch)"
}
prepare() {
cd "$srcdir/tor"
./autogen.sh
}
build() {
cd "$srcdir/tor"
## For performance testing - https://trac.torproject.org/projects/tor/ticket/11332
#pacman -S community/perf
#torrc: DisableDebuggerAttachment 0
#export CFLAGS='-Wall -g -O2 -pipe -fno-omit-frame-pointer'
#options=(!strip)
./configure \
--prefix=/usr --sysconfdir=/etc --localstatedir=/var \
--enable-systemd --enable-zstd
#--with-tcmalloc
#--enable-openbsd-malloc
make
}
check() {
cd "$srcdir/tor"
make test || true
}
package() {
cd "$srcdir/tor"
make DESTDIR="$pkgdir" install
rm -f "$pkgdir/etc/tor/tor-tsocks.conf"
install -Dm640 "$srcdir/torrc" "$pkgdir/etc/tor/torrc"
install -Dm644 "$srcdir/tor.service" "$pkgdir/usr/lib/systemd/system/tor.service"
install -Dm644 "$srcdir/tor.tmpfiles" "$pkgdir/usr/lib/tmpfiles.d/tor.conf"
install -Dm644 "$srcdir/tor.sysusers" "$pkgdir/usr/lib/sysusers.d/tor.conf"
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/tor/LICENSE"
}
|