blob: 65104aaa73b0d14e62f03796c1a324cf7591b18b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
pkgname=tor6-git
_branch=master
#_branch=maint-0.2.6
pkgver=0.2.9.2.alpha.22832
pkgrel=1
pkgdesc="An anonymizing overlay network (development version, route length 6)"
arch=('i686' 'x86_64' 'armv6h' 'armv7h')
url="http://www.torproject.org"
license=('BSD')
depends=('openssl>=1.0.2.a' 'ca-certificates' 'libevent' 'libseccomp')
makedepends=('asciidoc')
optdepends=('torsocks: for torify support')
conflicts=('tor')
provides=('tor')
install='tor.install'
backup=('etc/tor/torrc')
source=("git+https://git.torproject.org/tor.git#branch=${_branch}"
'torrc'
'tor.service' 'tor.tmpfiles' 'tor.sysusers' 'routelen6.patch')
sha256sums=('SKIP'
'e49f03ed46ce9cc4c4c53449c1cf7946bd363e9de98c73fe4618abc3b86950e9'
'5acd97eed1e4e175d5d547704a7d125009de6dc51d3c7163b7311e82fd34e9a2'
'37ff22a2e6f3dab412f08b46b86dede063538f6a32039d58a90d1212f188b379'
'4a27a177889c044ff4e3e1f6ab8bbb32211466d53d884974240dab67592343b2'
'0d7c27b8e1ab1fe24c28c031b4426306bb74d0d1d45a7138f5d147df65e36af9')
pkgver () {
cd "$srcdir/tor"
echo "$(grep AC_INIT configure.ac \
| sed 's/.*\[\(.*\)\].*/\1/;s/-/./g;s/.dev//').$(git rev-list --count origin/$_branch)"
}
prepare() {
cd "$srcdir/tor"
./autogen.sh
patch -p1 -i "$srcdir/routelen6.patch"
}
build() {
cd "$srcdir/tor"
## For performance testing - https://trac.torproject.org/projects/tor/ticket/11332
#pacman -S community/perf
#torrc: DisableDebuggerAttachment 0
#export CFLAGS='-Wall -g -O2 -pipe -fno-omit-frame-pointer'
#options=(!strip)
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var
#--with-tcmalloc
#--enable-openbsd-malloc
#--with-dmalloc
make
}
check() {
cd "$srcdir/tor"
make test || true
}
package() {
cd "$srcdir/tor"
make DESTDIR="$pkgdir" install
rm -f "$pkgdir/etc/tor/tor-tsocks.conf"
install -Dm640 "$srcdir/torrc" "$pkgdir/etc/tor/torrc"
install -Dm644 "$srcdir/tor.service" "$pkgdir/usr/lib/systemd/system/tor.service"
install -Dm644 "$srcdir/tor.tmpfiles" "$pkgdir/usr/lib/tmpfiles.d/tor.conf"
install -Dm644 "$srcdir/tor.sysusers" "$pkgdir/usr/lib/sysusers.d/tor.conf"
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/tor/LICENSE"
}
|