blob: 2c1e351054bcf921ffa916cba281a061c1af9789 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# Maintainer: Adrián Pérez de Castro <aperez@igalia.com>
pkgdesc='A powerful (and blazing fast) argument checker and function overloading system for Lua or LuaJIT'
pkgname='torch7-argcheck-git'
pkgver=r131.3cab0ae
pkgrel=1
makedepends=('cmake')
depends=('torch7-git>=r819')
conflicts=('torch7-argcheck')
provides=('torch7-argcheck')
arch=('x86_64' 'i686')
url='https://github.com/torch/argcheck'
license=('BSD')
source=("${pkgname}::git+${url}")
sha512sums=('SKIP')
pkgver () {
cd "${pkgname}"
(
set -o pipefail
git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
)
}
build () {
cd "${pkgname}"
cmake . -DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_BUILD_TYPE=Release
make
}
package () {
cd "${pkgname}"
make DESTDIR="${pkgdir}" install
# Move pure Lua modules
mkdir -p "${pkgdir}/usr/share/lua/5.1"
mv "${pkgdir}/argcheck" "${pkgdir}/usr/share/lua/5.1/"
}
|