blob: ead513ee28bfcfd43cd15c0598ec650d7e417e99 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Jingbei Li <i@jingbei.li>
pkgdesc='A CUDA backend for Torch7'
pkgname='torch7-cutorch-git'
pkgver=r1026.5e9d86c
pkgrel=1
makedepends=('cmake' 'git')
depends=('torch7-git>=r819' 'cuda')
conflicts=('torch7-cutorch')
provides=('torch7-cutorch')
arch=('x86_64' 'i686')
url='https://github.com/torch/cutorch'
license=('BSD')
source=("${pkgname}::git+${url}")
sha512sums=('SKIP')
pkgver(){
cd "${pkgname}"
(
set -o pipefail
git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
)
}
build(){
CFLAGS="${CFLAGS/-fno-plt/}"
CXXFLAGS="${CXXFLAGS/-fno-plt/}"
cd "${pkgname}"
CPATH=/usr/include/lua5.1 \
cmake . -DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_C_COMPILER=gcc-5 -DCMAKE_BUILD_TYPE=Release
make
}
package(){
cd "${pkgname}"
make DESTDIR="${pkgdir}" install
# Move Lua C module
mkdir -p "${pkgdir}/usr/lib/lua/5.1"
mv "${pkgdir}/usr/lib/libcutorch.so" "${pkgdir}/usr/lib/lua/5.1/"
# Move pure Lua modules
mkdir -p "${pkgdir}/usr/share/lua/5.1"
mv "${pkgdir}/usr/lua/cutorch" "${pkgdir}/usr/share/lua/5.1/"
rm -rf "${pkgdir}/usr/lua"
}
|