blob: 9e537b6651ff741a13a25341d6648f2ce1db2a84 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
# Previous maintainer: Ivan Shapovalov <intelfx@intelfx.name>
# Contributor: Felix Yan <felixonmars@archlinux.org>
# Contributor: Håvard Pettersson <mail@haavard.me>
# Contributor: naxuroqa <naxuroqa at gmail.com>
# Contributor: Boohbah <boohbah at gmail.com>
# Contributor: Kevin MacMartin <prurigro at gmail dot com>
pkgname=toxcore-git
pkgver=0.2.12.r26.ga71ddc7ea
pkgrel=1
pkgdesc="Peer to peer (serverless) instant messenger core"
arch=('i686' 'x86_64')
url="https://tox.chat/"
license=('GPL3')
depends=('glibc' 'libconfig' 'libsodium' 'libvpx' 'opus')
makedepends=('git' 'cmake')
provides=('toxcore' 'tox')
conflicts=('toxcore' 'tox')
backup=('etc/tox-bootstrapd.conf')
options=('staticlibs')
source=("git+https://github.com/TokTok/c-toxcore.git"
"toxcore.conf::https://raw.githubusercontent.com/archlinux/svntogit-community/packages/toxcore/trunk/toxcore.conf"
"toxcore.tmpfiles::https://raw.githubusercontent.com/archlinux/svntogit-community/packages/toxcore/trunk/toxcore.tmpfiles")
sha256sums=('SKIP'
'SKIP'
'SKIP')
prepare() {
cd "c-toxcore"
sed -i "s|/usr/local|/usr|" "other/bootstrap_daemon/tox-bootstrapd.service"
}
pkgver() {
cd "c-toxcore"
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "c-toxcore"
cmake \
-B "_build" \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX="/usr" \
-DCMAKE_INSTALL_LIBDIR="lib" \
./
make -C "_build"
}
check() {
cd "c-toxcore"
make -C "_build" test
}
package() {
cd "c-toxcore"
make -C "_build" DESTDIR="$pkgdir" install
install -Dm644 "$srcdir/toxcore.conf" -t "$pkgdir/usr/lib/sysusers.d"
install -Dm644 "$srcdir/toxcore.tmpfiles" "$pkgdir/usr/lib/tmpfiles.d/toxcore.conf"
install -Dm644 "other/bootstrap_daemon/tox-bootstrapd.service" -t "$pkgdir/usr/lib/systemd/system"
install -Dm644 "other/bootstrap_daemon/tox-bootstrapd.conf" -t "$pkgdir/etc"
}
|