blob: 2530c9d4de983cd5ad28891732106f8446544bad (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: Hexchain Tong <i at hexchain dot org>
pkgname=tpm2-tss-git
pkgver=r657.64b11df
_pkgname=TPM2.0-TSS
pkgrel=1
pkgdesc="TPM (Trusted Platform Module) 2.0 Software Stack (TSS)"
arch=('i686' 'x86_64')
provides=('tpm2-tss')
conflicts=('tpm2-tss')
url="https://github.com/01org/TPM2.0-TSS"
license=('custom')
makedepends=('git' 'cmocka' 'autoconf-archive')
depends=('gcc-libs')
source=('git+https://github.com/01org/TPM2.0-TSS.git')
md5sums=('SKIP')
pkgver() {
cd "$srcdir/$_pkgname"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cd "$srcdir/$_pkgname"
./bootstrap
./configure --prefix=/usr --sbindir=/usr/bin --disable-static
make
}
check() {
cd "$srcdir/$_pkgname"
make -k check
}
package() {
cd "$srcdir/$_pkgname"
make DESTDIR="$pkgdir/" install
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|