PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

# Maintainer: Julian Brost <julian@0x4a42.net>
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Rubin Simons <rubin@xs4all.nl>

pkgname=trac
pkgver=1.4.2
pkgrel=1
pkgdesc='Enhanced wiki and issue tracking system for software development projects'
arch=('any')
url="http://trac.edgewall.org/"
license=('BSD')
depends=(python2 python2-jinja python2-setuptools)
makedepends=(python2-babel)
optdepends=('python2-psycopg2: PostgreSQL database support'
            'python2-pygments: Syntax highlighting'
            'python2-docutils: reStructuredText support'
            'python2-babel: localization support'
            'python2-pytz: complete list of time zones')
install=trac.install
source=(https://download.edgewall.org/trac/Trac-$pkgver.tar.gz
        tracd.service)
sha256sums=('42372fcd9f2ac46264656287fe6edb8230f59b44e991ee098b399f1bb475ae8f'
            '3f050f1c9367b1b28e18a6ff0088f991676a9fbba3f5177859ce4db64f95ca42')

prepare() {
  cd "$srcdir"/Trac-$pkgver
  sed -i 's:^#!/usr/bin/env python$:#!/usr/bin/env python2:' \
    trac/admin/console.py \
    trac/test.py \
    trac/web/cgi_frontend.py \
    trac/web/fcgi_frontend.py \
    trac/web/standalone.py
}

package() {
  cd "$srcdir"/Trac-$pkgver
  python2 setup.py install --prefix=/usr --root="$pkgdir"
  install -D -m644 COPYING "$pkgdir"/usr/share/licenses/trac/COPYING
  install -Dm0644 "$srcdir"/tracd.service "$pkgdir"/usr/lib/systemd/system/tracd.service
}