PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Maintainer: Robin Broda <robin at broda dot me>

_pkgname=trachet
pkgname=${_pkgname}-git
pkgver=r313.cd2be17
pkgrel=1
pkgdesc='Tell you what is happening on your terminal'
arch=('any')
url="https://github.com/saitoha/${_pkgname}"
license=('GPL')
depends=('python2')
makedepends=('git' 'python2-setuptools')
source=("git+${url}"
        'git+https://github.com/saitoha/tff')
md5sums=('SKIP' 'SKIP')

pkgver() {
	cd "${_pkgname}"
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
	cd "${_pkgname}"

	git submodule init
	git config submodule.trachet/tff.url ${srcdir}/tff
	git submodule update
}

build() {
	cd "${_pkgname}"

	python2 setup.py build
}

package() {
	cd "${_pkgname}"

	python2 setup.py install --root="${pkgdir}" --optimize=1 --skip-build
	echo -n > "${pkgdir}"/usr/lib/python2.7/site-packages/trachet-*-py2.7.egg-info/requires.txt
}