blob: 979fb52c6eca0eec7725a3092d3e2219427905c6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Maintainer: Ivan Gabaldon <aur[at]inetol.net>
# Contributor: sukanka <su975853527 at gmail.com>
pkgname=tradingview
pkgver=2.7.1
pkgrel=2
pkgdesc='TradingView is a charting platform for traders and investors'
arch=('x86_64')
url='https://www.tradingview.com/desktop/'
license=('custom:proprietary')
depends=('alsa-lib'
'at-spi2-core'
'cairo'
'dbus'
'expat'
'gcc-libs'
'glib2'
'glibc'
'gtk3'
'hicolor-icon-theme'
'libcups'
'libdrm'
'libsecret'
'libx11'
'libxcb'
'libxcomposite'
'libxdamage'
'libxext'
'libxfixes'
'libxkbcommon'
'libxrandr'
'mesa'
'nspr'
'nss'
'pango')
makedepends=('links'
'squashfs-tools')
source=("$pkgname-$pkgver.snap::https://api.snapcraft.io/api/v1/snaps/download/nJdITJ6ZJxdvfu8Ch7n5kH5P99ClzBYV_48.snap")
b2sums=('979958b07225cb2cd0b132d98b7e8727cca2b6fca8fd5608b16f9c9daddbe39c21b9ea94ceac47447c79e97cb6ca15fab63bfe0fadbc8d221ba75cd71dc428f8')
prepare() {
## EULA
links -width 80 -dump https://www.tradingview.com/policies/ | \
sed -n '/Terms of Use, Policies and Disclaimers/,/TradingView may update these Rules at any time./p' > "$srcdir/EULA.txt"
## Extract
unsquashfs -q -f -d "$pkgname-$pkgver/" "$pkgname-$pkgver.snap"
mv "$pkgname-$pkgver/meta/gui/icon.png" "$srcdir/"
mv "$pkgname-$pkgver/meta/gui/$pkgname.desktop" "$srcdir/"
sed -n -e 's@${SNAP}/meta/gui/icon.png@'"$pkgname"'@g' \
-e 's@^Categories=Finance;$@Categories=Office;Finance;@g' \
"$srcdir/$pkgname.desktop"
rm -r "$pkgname-$pkgver/"{data-dir/,gnome-platform/,lib/,meta/,scripts/,usr/,*.sh}
}
package() {
install -d "$pkgdir/opt/$pkgname"
cp -r "$srcdir/$pkgname-$pkgver/"* "$pkgdir/opt/$pkgname"
install -d "$pkgdir/usr/bin"
ln -s "/opt/$pkgname/$pkgname" "$pkgdir/usr/bin/$pkgname"
install -Dm644 "$srcdir/icon.png" "$pkgdir/usr/share/icons/hicolor/512x512/apps/$pkgname.png"
install -Dm644 "$srcdir/$pkgname.desktop" -t "$pkgdir/usr/share/applications/"
install -Dm644 "$srcdir/EULA.txt" -t "$pkgdir/usr/share/licenses/$pkgname/"
}
|