blob: d19dd2fd98b43ab40c714db9114b7813fe1b498a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=traefik-git
pkgver=2.2.1.r15.g7928e6d0c
pkgrel=1
pkgdesc="The cloud native edge router"
arch=('i686' 'x86_64')
url="https://containo.us/traefik/"
license=('MIT')
depends=('glibc')
makedepends=('git' 'go' 'go-bindata')
provides=('traefik')
conflicts=('traefik')
backup=('etc/traefik/traefik.toml'
'etc/traefik/traefik.yaml'
'etc/traefik/traefik.yml')
source=("git+https://github.com/containous/traefik.git"
"traefik.service::https://git.archlinux.org/svntogit/community.git/plain/trunk/traefik.service?h=packages/traefik"
"traefik.sysusers::https://git.archlinux.org/svntogit/community.git/plain/trunk/traefik.sysusers?h=packages/traefik")
sha256sums=('SKIP'
'SKIP'
'SKIP')
pkgver() {
cd "traefik"
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "traefik"
go generate
go build \
-buildmode=pie \
-ldflags "-extldflags $LDFLAGS" \
-trimpath \
-mod=readonly \
-modcacherw \
./cmd/traefik
}
check() {
cd "traefik"
go test \
-mod=readonly \
./...
}
package() {
cd "traefik"
install -Dm755 "traefik" -t "$pkgdir/usr/bin"
install -Dm644 "$srcdir/traefik.service" -t "$pkgdir/usr/lib/systemd/system"
install -Dm644 "$srcdir/traefik.sysusers" "$pkgdir/usr/lib/sysusers.d/traefik.conf"
install -Dm644 "LICENSE.md" -t "$pkgdir/usr/share/licenses/traefik"
}
|