PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60

# Maintainer: Mubashshir <ahmubashshir@gmail.com>
# pkg: github iamkroot/trakt-scrobbler
pkgname=trakt-scrobbler
pkgver=1.2.1
pkgrel=2
pkgdesc="Automatically scrobble TV show episodes and movies you are watching to Trakt.tv! It keeps a history of everything you've watched!"

arch=(any)
url=https://github.com/iamkroot/trakt-scrobbler
license=(GPL2)
depends=(
    "systemd"
    "python-appdirs<2" #auto-deps
    "python-appdirs>=1.4.3" #auto-deps
    "python-cleo<1" #auto-deps
    "python-cleo>=0.7.6" #auto-deps
    "python-confuse<2" #auto-deps
    "python-confuse>=1.3.0" #auto-deps
    "python-guessit<4" #auto-deps
    "python-guessit>=3.1.0" #auto-deps
    "python-gobject<4" #auto-deps
    "python-gobject>=3.34.0" #auto-deps
    "python-pysocks<2" #auto-deps
    "python-pysocks>=1.7.1" #auto-deps
    "python-requests<3" #auto-deps
    "python-requests>=2.22.0" #auto-deps
)

makedepends=(
    python-setuptools
    python-dephell
    go-md2man
    gzip
)
source=(
    "$pkgname-$pkgver.tar.gz::https://github.com/iamkroot/$pkgname/archive/v$pkgver.tar.gz"
    "trakts-man.md"
    "trakts.zsh"
)
sha256sums=('820bcab20926ec00051d2a90472ef80bb6a33e41948249d2d12eb43b6530b752'
            '81c3fb93bf01c0e6c0bbc9b2ef853da3f691bc3c50b4a87a68072b11ba72691c'
            '6b6c3f55ab153a9dc749e67acd6e091b5d1e9e35c3b51af4d2f1c687e8c8fab8')

prepare() {
    cd "$srcdir/$pkgname-$pkgver"
    dephell deps convert --from pyproject.toml --to setup.py
}
build() {
    cd "$srcdir/$pkgname-$pkgver"
    python setup.py build
    go-md2man -in "$srcdir/trakts-man.md" 2>/dev/null|gzip -n > trakts.1.gz
}

package()
{
    cd "$srcdir/$pkgname-$pkgver"
    python setup.py install --root="$pkgdir" --optimize=1 --skip-build
    install -Dm644 "trakts.1.gz" "$pkgdir/usr/share/man/man1/trakts.1.gz"
    install -Dm755 "$srcdir/trakts.zsh" "$pkgdir/usr/share/zsh/site-functions/_trakts"
}