blob: 1eb7a159ada3f59e8cee260aacf9521d3716b155 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
|
# Maintainer: Mubashshir <ahmubashshir@gmail.com>
# from: pypi
# what: trakt-scrobbler
pkgname=trakt-scrobbler
pkgver=1.5.0
pkgrel=1
pkgdesc="Automatically scrobble TV show episodes and movies you are watching to Trakt.tv! It keeps a history of everything you've watched!"
arch=(any)
url=https://github.com/iamkroot/trakt-scrobbler
license=(GPL2)
depends=(
"systemd"
'python-requests<3.0.0' #auto-deps
'python-requests>=2.25.1' #auto-deps
'python-urllib3<2.0.0' #auto-deps
'python-urllib3>=1.26.0' #auto-deps
'python-guessit<4.0.0' #auto-deps
'python-guessit>=3.3.1' #auto-deps
'python-appdirs<2.0.0' #auto-deps
'python-appdirs>=1.4.4' #auto-deps
'python-cleo<0.9.0' #auto-deps
'python-cleo>=0.8.1' #auto-deps
'python-confuse<3.0' #auto-deps
'python-confuse>=2.0' #auto-deps
'python-urlmatch<2.0.0' #auto-deps
'python-urlmatch>=1.0.1' #auto-deps
'python-pydantic<2.0.0' #auto-deps
'python-pydantic>=1.10.2' #auto-deps
'python-toml<0.11.0' #auto-deps
'python-toml>=0.10.2' #auto-deps
)
makedepends=(
python-poetry-core
python-build
python-installer
python-wheel
go-md2man
gzip
)
source=(
"$pkgname-$pkgver.tar.gz::https://files.pythonhosted.org/packages/source/${pkgname::1}/$pkgname/$pkgname-$pkgver.tar.gz"
"trakts-man.md"
)
sha256sums=('012427205e400bc24c38a9dc24ca600c779574b8837492ccdb229aaca1ce7bc3'
'81c3fb93bf01c0e6c0bbc9b2ef853da3f691bc3c50b4a87a68072b11ba72691c')
prepare() {
cd "$srcdir/$pkgname-$pkgver"
sed -i 's/cleo\s/cleo_v0 /' \
trakt_scrobbler/console.py \
trakt_scrobbler/commands/command.py
}
build() {
cd "$srcdir/$pkgname-$pkgver"
python -m build --no-isolation --wheel
go-md2man -in "$srcdir/trakts-man.md" 2>/dev/null|gzip -n > trakts.1.gz
}
package()
{
cd "$srcdir/$pkgname-$pkgver"
_py=$(python --version)
_py=${_py%%.*}
python -m installer --destdir="$pkgdir" \
"dist/${pkgname//-/_}-${pkgver%.r*}-py${_py##* }-none-any.whl"
install -Dm644 "trakts.1.gz" "$pkgdir/usr/share/man/man1/trakts.1.gz"
install -Dm755 "completions/trakts.zsh" "$pkgdir/usr/share/zsh/site-functions/_trakts"
}
|