summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: d14494bf9b050607c92f492c142724c0b7ceca73 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
# Maintainer: Konstantin Shalygin <k0ste@k0ste.ru>
# Contributor: Konstantin Shalygin <k0ste@k0ste.ru>
# Contributor: Alexander Mamzikov <av.mamzikov@gmail.com>
# Contributor: Dobroslaw Kijowski <dobo90_at_gmail.com>
# Contributor: Paul N. Maxwell <msg.maxwel@gmail.com>

pkgbase='transgui'
pkgname=("${pkgbase}-qt" "${pkgbase}-gtk")
pkgver='5.18.8.f'
pkgrel='1'
pkgdesc='Transmission BitTorrent client'
arch=('x86_64' 'aarch64')
_url="https://github.com/lighterowl"
url="${_url}/${pkgbase}"
license=("GPL")
makedepends=('git' 'lazarus' 'qt6pas' 'gtk2')
source=("${url}/archive/refs/tags/v${pkgver}.tar.gz"
        "${pkgbase}.desktop")
sha256sums=('86107eca8982402ff6292f93e361957b4017e48d32d23516d7ec97b2dae6c7d6'
            '6ee61ee4b01445ef67cc76abaee051c17043b57a743a977a2528a4c78a9a638b')

prepare() {
  cd "${pkgbase}-${pkgver}"
  mkdir -v "../build-qt6" "../build-gtk2"

  # Add custom dependency
  git clone --progress --branch="${pkgbase}" "${_url}/synapse.git" "synapse/source/lib"
}

_build() {
  cd "${pkgbase}-${pkgver}"

  lazbuild "${pkgbase}.lpi" \
  --lazarusdir="/usr/lib/lazarus" \
  --build-mode="Release" \
  --primary-config-path="../build-${1}" \
  --widgetset="${1}"

  install -dm0755 "${pkgdir}/usr/share/${pkgbase}/lang"
  install -dm0755 "${pkgdir}/usr/share/doc/${pkgbase}"
  install -Dm0755 "units/${pkgbase}" -t "${pkgdir}/usr/bin"
  install -Dm0644 "lang/${pkgbase}".* "${pkgdir}/usr/share/${pkgbase}/lang"
  install -Dm0644 "README.md" -t "${pkgdir}/usr/share/doc/${pkgbase}"
  install -Dm0644 "LICENSE" -t "${pkgdir}/usr/share/doc/${pkgbase}"
  install -Dm0644 "${pkgbase}.png" -t "${pkgdir}/usr/share/pixmaps"
  install -Dm0644 "../${pkgbase}.desktop" -t "${pkgdir}/usr/share/applications"

  rm "${pkgdir}/usr/share/${pkgbase}/lang/${pkgbase}.template"
}

package_transgui-qt() {
  depends=('qt6pas')
  conflicts=('transgui-gtk2-git' 'transgui-qt4-git' 'transmission-remote-gui-qt4'
             'transmission-remote-gui-gtk2' 'transmission-remote-gui-bin' 'transgui-gtk')
  _build "qt6"
}

package_transgui-gtk() {
  depends=('gtk2')
  conflicts=('transgui-gtk2-git' 'transgui-qt4-git' 'transmission-remote-gui-qt4'
             'transmission-remote-gui-gtk2' 'transmission-remote-gui-bin' 'transgui-qt')
  _build "gtk2"
}

check() {
  cd "${pkgbase}-${pkgver}/test"

  lazbuild "transguitest.lpi" --lazarusdir="/usr/lib/lazarus"
  ./units/transguitest -a
}