blob: a42d1060fcc84753142a14ab0998bfb1a428de53 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=tree-sitter-typescript
pkgver=0.23.2
pkgrel=2
pkgdesc="TypeScript grammar for tree-sitter"
arch=('i686' 'x86_64')
url="https://github.com/tree-sitter/tree-sitter-typescript"
license=('MIT')
groups=('tree-sitter-grammars')
depends=('glibc')
makedepends=('nodejs' 'tree-sitter-cli')
provides=('libtree-sitter-typescript.so')
options=('staticlibs')
source=("$pkgname-$pkgver-src.tar.gz::https://github.com/tree-sitter/tree-sitter-typescript/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=('2c4ce711ae8d1218a3b2f899189298159d672870b5b34dff5d937bed2f3e8983')
build() {
cd "$pkgname-$pkgver"
tree-sitter generate
CFLAGS="$CFLAGS -ffat-lto-objects" \
make
}
check() {
cd "$pkgname-$pkgver"
#tree-sitter test
}
package() {
cd "$pkgname-$pkgver"
make DESTDIR="$pkgdir" PREFIX="/usr" install
install -Dm644 "LICENSE" -t "$pkgdir/usr/share/licenses/tree-sitter-typescript"
install -Dm644 "README.md" -t "$pkgdir/usr/share/doc/tree-sitter-typescript"
}
|