blob: 28a5553f53a2d18977f179c693017044c4d31308 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Carlos Aznarán <caznaranl@uni.pe>
# Contributor: Antonio Rojas <arojas@archlinux.org>
# Contributor: Felix Yan <felixonmars@archlinux.org>
pkgname=treefrog-framework
pkgver=2.12.1
pkgrel=1
pkgdesc="High-speed C++ MVC Framework for Web Application"
arch=(x86_64)
url="https://github.com/${pkgname/-/}/${pkgname}"
license=(BSD-3-Clause)
depends=(qt5-declarative mongo-c-driver)
makedepends=(cmake qt5-tools)
source=(${pkgname}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz)
sha512sums=('1fa68eb066ff0a3671208e45441a8d95544517f702de6e44d7e2b6661a31fd38ab0ab925f4ec6da444d7d03399e58068d775d37884af466e3dae28c5e6eda91f')
prepare() {
cd ${pkgname}-${pkgver}
rm -r 3rdparty
sed -i 's|INCLUDEPATH += ../include ../3rdparty/lz4/lib|INCLUDEPATH += ../include|' src/corelib.pro
sed -i 's|LIBS += ../3rdparty/lz4/lib/liblz4.a|LIBS += -llz4|' src/corelib.pro
sed -i 's|INCLUDEPATH += ../3rdparty/mongo-driver/src/libmongoc/src/mongoc ../3rdparty/mongo-driver/src/libbson/src|INCLUDEPATH += /usr/include/libmongoc-1.0 /usr/include/libbson-1.0|' src/corelib.pro
sed -i 's|LIBS += ../3rdparty/mongo-driver/src/libmongoc/libmongoc-static-1.0.a ../3rdparty/mongo-driver/src/libbson/libbson-static-1.0.a|LIBS += -lmongoc-1.0 -lbson-1.0|' src/corelib.pro
sed -i 's|exit $RET||' configure
}
build() {
cd ${pkgname}-${pkgver}
./configure --prefix=/usr
cd src
make
}
package() {
cd ${pkgname}-${pkgver}/src
make INSTALL_ROOT="${pkgdir}" install
install -Dm644 ../copyright "${pkgdir}"/usr/share/licenses/${pkgname}/copyright
}
|