PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# Maintainer: ALTER Identity <dev@truealter.com>
#
# AUR package for the @truealter/cli npm release.
#
# Publish flow (post-publish):
#   1. Compute the SHA256 of the tarball:
#        curl -fsSL https://registry.npmjs.org/@truealter/cli/-/cli-${pkgver}.tgz \
#          | sha256sum
#   2. Replace sha256sums=('SKIP') with the real digest.
#   3. makepkg --printsrcinfo > .SRCINFO
#   4. git add PKGBUILD .SRCINFO && git commit && git push
#
# Push target requires an AUR account and an uploaded SSH public key;
# see https://aur.archlinux.org/account. Not configured on desk yet --
# this PKGBUILD lives in the alter-cli repo as a staging area until
# the AUR credential is in place.

pkgname=truealter-cli
_npmname='@truealter/cli'
pkgver=0.7.0
pkgrel=1
pkgdesc='ALTER identity CLI -- login once, authenticated everywhere'
arch=('any')
url='https://truealter.com'
license=('Apache-2.0')
depends=('nodejs>=20')
makedepends=('npm')
source=("https://registry.npmjs.org/${_npmname}/-/cli-${pkgver}.tgz")
noextract=("cli-${pkgver}.tgz")
# sha256 pinned to published 0.7.0 tarball.
# Recompute on every pkgver bump:
#   curl -fsSL https://registry.npmjs.org/@truealter/cli/-/cli-${pkgver}.tgz \
#     -o cli-${pkgver}.tgz && sha256sum cli-${pkgver}.tgz
# CI rejects 'SKIP' values via .github/workflows/ci.yml.
# NOTE: /boogie-time §1.3 still gates Phase A on major version >= 1.0.0;
# this PKGBUILD tracks the latest public minor for keep-pace hygiene
# and will move to v1.0.0 in the launch-trigger PR.
sha256sums=('187ebe653fdb9075b7d4d5d26fc903ed6c340f3eed0ea7c68495b2bffaf031ad') # pragma: allowlist secret

package() {
  cd "${srcdir}"
  npm install -g --prefix "${pkgdir}/usr" "./cli-${pkgver}.tgz"

  # Strip $srcdir references that npm bakes into generated package.json files.
  find "${pkgdir}/usr" -type f -name 'package.json' \
    -exec sed -i "s|${srcdir}|/tmp|g" {} \;

  # Fix permissions -- npm's default umask leaves directories 700.
  chmod -R u=rwX,go=rX "${pkgdir}"
  chmod 755 "${pkgdir}/usr/bin/alter"
}