blob: 69a538a6dd96bec7141ba67861b0be1d24999593 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
|
# Maintainer: Kirill Goncharov <kdgoncharov at gmail dot com>
# Contributor: Devin Cofer <ranguvar[at]ranguvar[dot]io>
# Contributor: Francisco Giordano <frangio.1@gmail.com>
pkgname=truffle
pkgver=5.1.50
pkgrel=1
pkgdesc='A development framework for Ethereum smart contracts'
url='https://github.com/trufflesuite/truffle'
arch=('any')
license=('MIT')
source=("https://registry.npmjs.org/truffle/-/truffle-${pkgver}.tgz")
noextract=("truffle-${pkgver}.tgz")
makedepends=('npm')
depends=('nodejs')
sha256sums=('f1b73c46c8f17f406e34ac8060b549836206ad07908dd6a6b930e3e02430faf1')
package() {
npm install -g --production --prefix "$pkgdir/usr" "truffle-${pkgver}.tgz"
tar -xf "truffle-${pkgver}.tgz" package/LICENSE
install -D -m644 package/LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
# -> https://wiki.archlinux.org/index.php/Node.js_package_guidelines
# Non-deterministic race in npm gives 777 permissions to random directories.
# See https://github.com/npm/npm/issues/9359 for details.
find "${pkgdir}"/usr -type d -exec chmod 755 {} +
# npm gives ownership of ALL FILES to build user
# https://bugs.archlinux.org/task/63396
chown -R root:root "$pkgdir"
}
|