blob: cc02b6b0d8b595c84cf98212d16aee816bcfd7f8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: dplusplus <echo cmFuZG9tdGVzdG5hbWUtYXQtZ21haWwoZG90KWNvbQo= | base64 -d>
# Contributor: Sefa Eyeoglu <contact@scrumplex.net>
# Contributor: Philip Abernethy <chais.z3r0@gmail.com>
_pkgname=tshock
pkgname=${_pkgname}-bin
pkgver=5.2.3
_terraria_ver=1.4.4.9
# Because of tag 4.2200 is 4.2.2.1228 and tag 4.2202 is 4.2.2.0224 epoch must be 1
epoch=1
pkgrel=1
pkgdesc="A Terraria Server administration modification that runs on the open source TerrariaAPI."
arch=("x86_64")
url="https://github.com/Pryaxis/TShock"
license=("GPL3")
depends=("mono" "tmux")
provides=($_pkgname)
conflicts=($_pkgname)
source=(
"${_pkgname}_${pkgver}.zip::https://github.com/Pryaxis/TShock/releases/download/v${pkgver}/TShock-${pkgver}-for-Terraria-${_terraria_ver}-linux-amd64-Release.zip"
"${_pkgname}.sh"
"default.conf"
"${_pkgname}@.service"
"${_pkgname}.sysusers"
"${_pkgname}.tmpfiles"
"${_pkgname}.install"
)
noextract=("${_pkgname}_${pkgver}.zip")
sha512sums=('f612ec555afb37e1aa597c1eb418012a9f7fa233f162b8c1c94bf749648ba8fd416c8a5de5e5628839b3082041ca68602ac8ddb9d1dc86f9f82fec4a2c411506'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
)
install="tshock.install"
backup=("etc/conf.d/${_pkgname}/default.conf")
package() {
install -Dm755 "${_pkgname}.sh" "${pkgdir}/usr/bin/${_pkgname}"
install -Dm644 "default.conf" "${pkgdir}/etc/conf.d/${_pkgname}/default.conf"
# Unzip server files
install -d "${pkgdir}/srv/${_pkgname}"
bsdtar -x -f "${_pkgname}_${pkgver}.zip" -C "${pkgdir}/srv/${_pkgname}"
install -Dm644 "${_pkgname}@.service" "${pkgdir}/usr/lib/systemd/system/${_pkgname}@.service"
install -Dm644 "${_pkgname}.sysusers" "${pkgdir}/usr/lib/sysusers.d/${_pkgname}.conf"
install -Dm644 "${_pkgname}.tmpfiles" "${pkgdir}/usr/lib/tmpfiles.d/${_pkgname}.conf"
}
|